Каков наилучший способ проверки пароля и подтверждения пароля в grails?

Question

У меня есть класс домена, который содержит пароль & поля password_confirm. Эти два проверяются отдельно. Какова наилучшая практика для создания проверки того, что эти два равны?

Answer 1

class User { 

    String password 
    String passwordConfirm 


    static constraints = { 
    password blank: false, nullable: false, minSize: 8, maxSize: 64, validator: {password, obj -> 
     def password2 = obj.passwordConfirm 
     password2 == password ? true : ['invalid.matchingpasswords'] 
    } 
    } 

} 

Затем добавьте следующую строку в файл messages.properties ...

User.password.invalid.matchingpasswords=Passwords do not match 

Когда user.save() или user.validate() вызывается, это вызовет автоматически.

Answer 2

Предлагаю вам использовать плагин безопасности для Grails, возможно, Shiro или Spring Security Core.

documentation В Спринг безопасности Ядра есть пример изменения пароля:

def updatePassword = { 
    String username = session['SPRING_SECURITY_LAST_USERNAME'] 
    if (!username) { 
     flash.message = 'Sorry, an error has occurred' 
     redirect controller: 'login', action: 'auth' 
     return 
    } 
    String password = params.password 
    String newPassword = params.password_new 
    String newPassword2 = params.password_new_2 
    if (!password || !newPassword || !newPassword2 || newPassword != newPassword2) { 
     flash.message = 'Please enter your current password and a valid new password' 
     render view: 'passwordExpired', model: [username: session['SPRING_SECURITY_LAST_USERNAME']] 
     return 
    } 

    User user = User.findByUsername(username) 
    if (!passwordEncoder.isPasswordValid(user.password, password, null /*salt*/)) { 
     flash.message = 'Current password is incorrect' 
     render view: 'passwordExpired', model: [username: session['SPRING_SECURITY_LAST_USERNAME']] 
     return 
    } 

    if (passwordEncoder.isPasswordValid(user.password, newPassword, null /*salt*/)) { 
     flash.message = 'Please choose a different password from your current one' 
     render view: 'passwordExpired', model: [username: session['SPRING_SECURITY_LAST_USERNAME']] 
     return 
    } 

    user.password = newPassword 
    user.passwordExpired = false 
    user.save() // if you have password constraints check them here 

    redirect controller: 'login', action: 'auth' 
}