Изменение цели анимации

Question

Невозможно переключить анимацию с одного объекта на другой. Идентификатор изменяется (он печатает «мир» в журнале), но он не передает анимацию: hello все еще мигает и world является статическим.

Он работает правильно только при звонке a.restart(). Когда нет функций, просто привязки, вы можете использовать onChanged и контролировать, как анимация останавливается (завершается или приостанавливается) if (running) { complete(); restart(); }.

import QtQuick 2.5 

Column { 
    ColorAnimation { 
     id: a 

     target: lab1 
     property: "color" 

     running: true 
     loops: Animation.Infinite 
     duration: 500 

     from: "black" 
     to: "red" 
    } 

    Text { 
     id: lab1 

     text: "hello" 

     MouseArea { 
      anchors.fill: parent 
      onClicked: { 
       a.target = lab2 
       console.log("changed") 
       console.log(a.target.text) 
      } 
     } 
    } 

    Text { 
     id: lab2 

     text: "world" 
    } 
} 

Answer 1

Я буду использовать это сейчас (только что добавили onTargetChanged):

import QtQuick 2.5 

Column { 
    ColorAnimation { 
     id: a 

     target: lab1 

     onTargetChanged: { 
      if (running) { complete(); restart(); } 
     } 

     property: "color" 

     running: true 
     loops: Animation.Infinite 
     duration: 500 

     from: "black" 
     to: "red" 
    } 

    Text { 
     id: lab1 

     text: "hello" 

     MouseArea { 
      anchors.fill: parent 
      onClicked: { 
       a.target = lab2 
       console.log("changed") 
       console.log(a.target.text) 
      } 
     } 
    } 

    Text { 
     id: lab2 

     text: "world" 
    } 
} 

И с привязкой (анимация переключается на другую метку при нажатии):

import QtQuick 2.5 

Column { 
    id: root 

    ColorAnimation { 
     id: a 

     target: ma.pressed ? lab2 : lab1 

     onTargetChanged: { 
      if (running) { complete(); restart(); } 
     } 

     property: "color" 

     running: true 
     loops: Animation.Infinite 
     duration: 500 

     from: "black" 
     to: "red" 
    } 

    Text { 
     id: lab1 

     text: "hello" 

     MouseArea { 
      id: ma 
      anchors.fill: parent 
     } 
    } 

    Text { 
     id: lab2 

     text: "world" 
    } 
} 

Answer 2

Вы должны остановить анимацию перед изменением цели:

a.running = false 
a.target = lab2 
a.running = true 

Он отлично работает для меня