Deserialize Существующий XML-файл в VB.NET

Question

Я изменяю приложение VB.NET для использования XmlSerializer вместо XMLDocument для чтения/записи в файл настроек XML и сохранения обратной совместимости.

Вот пример содержимого XML-файла:

<?xml version="1.0" encoding="utf-8"?> 
<configuration> 
    <appSettings> 
    <postHistory> 
     <postFile>a.txt</postFile> 
     <postFile>b.txt</postFile> 
     <postFile>c.txt</postFile> 
    </postHistory> 
    </appSettings> 
    <SettingsPath>d.txt</SettingsPath> 
</configuration> 

Вот классы я придумал, что правильно десериализации исходный файл.

Imports System.Xml.Serialization 
Imports System.Collections.Generic 

<XmlRoot("configuration")> 
Public Class LocalSettings 
    <XmlElement("appSettings")> 
    Public appSettings As New postHistory() 
    Public SettingsPath As String = "" 
End Class 

Public Class postHistory 
    Public postHistory As New SubSettings() 
End Class 

Public Class SubSettings 
    <XmlElement("postFile")> 
    Public postHistory As New List(Of String) 
End Class 

Это код, используемый для десериализации файла:

Public Shared Function GetLocalSettings(ByVal filePath As String) As LocalSettings 
    Dim lSettings As New LocalSettings() 

    Try 
     Dim xs As New XmlSerializer(GetType(LocalSettings)) 
     Using fs As New FileStream(filePath, FileMode.Open) 
     lSettings = xs.Deserialize(fs) 
     End Using 
    Catch ex As Exception 
     ' Handle exception 
    End Try 

    Return lSettings 
    End Function 

Это решение работает, но чувствует себя неловко. Есть ли более оптимальный способ де-сериализации, который не требует вложения списка «postHistory» в двух подклассах?

Answer 1

Вы можете использовать XmlArrayAttribute(string name), чтобы указать, что список должен быть сериализован на двух уровнях, при этом внешний элемент контейнера имеет указанное имя. Затем вы можете использовать XmlArrayItemAttribute(string name), чтобы указать имя внутреннего элемента.

Таким образом:

<XmlRoot("configuration")> 
Public Class LocalSettings 
    <XmlElement("appSettings")> 
    Public appSettings As New postHistory() 
    Public SettingsPath As String = "" 
End Class 

Public Class postHistory 
    <XmlArray("postHistory")> 
    <XmlArrayItem("postFile")> 
    Public postHistory As New List(Of String) 
End Class 

Это позволяет SubSettings класс должен быть устранен.

Образец fiddle.

Для получения дополнительной информации см. Controlling XML Serialization Using Attributes.