Вставить гиперссылку в столбец с данными

Question

Я пытаюсь вставить гиперссылки на столбец А, который имеет данные. например, A1 является заголовком; A2 будет 12345 с гиперссылкой http://123.1.1.1/?id=12345

В настоящее время я запускаю макрос на листе, который содержит около 11000 строк. это было около часа, оно все еще работает ...

Кроме того, пытаясь увидеть, может ли этот единственный макрос работать на всех листах.

Ниже мой макрос

Sub AddUrlSheet1() 
With Worksheets(1) 

Set R = ActiveSheet.Range("a2", ActiveSheet.Range("a2").End(xlDown)) 
R.Select 

For Each R In Selection.Cells 

.Hyperlinks.Add Anchor:=R, _ 
Address="http://123.1.1.1/" & R.Value 

Next R 
End With 
End Sub 

Answer 1

Попробуй это:

Sub AddUrlSheet1() 
    Application.ScreenUpdating = False 
    Application.Calculation = xlCalculationManual 
    ' 
    Dim LastUsedRow As Long 
    Dim r As Range, c As Range 
    With ActiveSheet 
     LastUsedRow = .Columns("A").Cells.Find("*", SearchOrder:=xlByRows, LookIn:=xlFormulas, SearchDirection:=xlPrevious).Row 
     Set r = .Range(.Cells(2, 1), .Cells(LastUsedRow, 1)) 
    End With 
    ' 
    For Each c In r 
     c.Hyperlinks.Add Anchor:=c, Address:="http://123.1.1.1/" & c.Value 
    Next c 
    Application.Calculation = xlCalculationAutomatic 
    Application.ScreenUpdating = True 
End Sub 

Это добавляет гиперссылка на все клетки, которые в настоящее время имеют значение в них в столбце A.

Answer 2

Вместо цикла клетки с помощью ячейку, используйте Hyperlink() с Formula, чтобы это сделать. Если R значения в столбце А, это будет заполнить гиперссылка в столбце B.

Sub t() 
Dim rng As Range 
' Note: Update the `10` to match your lastRow 
Set rng = Range("B2:B" & ActiveSheet.Range("a2").End(xlDown).Row) 

rng.FormulaR1C1 = "=HYPERLINK(""http://123.1.1.1/""&RC[-1],""Link"")" 

End Sub 

Если вы должны перебрать уже существующие данные, @ ответ Криса выглядит довольно хорошо.