Получение только последовательных данных в степени 2 при отправке алфавитов

Question

Я пытаюсь выполнить простой эксперимент с модулем Arduino Uno и BlueSmirf Bluetooth от Sparkfun (documentation).

Моя установка оборудования выглядит следующим образом:

Arduino(power through USB)->BlueSmirf  ---(bluetooth)--> PC(no wired connection the the Arduino)->RealTerm 

На Arduino, следующий эскиз работает:

#include <SoftwareSerial.h> 

int txPin = 2; 
int rxPin = 3; 

SoftwareSerial bluetooth(txPin, rxPin); 

void setup() { 
    bluetooth.begin(115200); 
    delay(100); 
} 

void loop() { 
    String textToSend = "abcdefghijklmnopqrstuvw123456789"; 
    bluetooth.print(textToSend); 
    delay(5000); 
} 

Теперь, Bluetooth подключается к ПК просто отлично, но когда я инспектировать COM-порт в RealTerm, я получаю только следующие данные:

abdhp1248 

Где остановились g буквы и цифры идут? Кажется, что все буквы, следующие за степенью двух (т. Е. A = 1, b = 2, d = 4, h = 8, p = 16), но все остальное. Это просто совпадение?

Answer 1

Я думаю, что вы используете последовательный порт слишком быстро. Согласно комментариям в примере BlueSmirf от sparkfun на https://learn.sparkfun.com/tutorials/using-the-bluesmirf - «115200 может быть слишком быстрым, чтобы NewSoftSerial мог надежно передавать данные».

Уменьшите скорость передачи до 9600, используя приведенный ниже пример кода, измененный с указанной веб-страницы.

/* 
    Example Bluetooth Serial Passthrough Sketch 
by: Jim Lindblom 
SparkFun Electronics 
date: February 26, 2013 
license: Public domain 

This example sketch converts an RN-42 bluetooth module to 
communicate at 9600 bps (from 115200), and passes any serial 
data between Serial Monitor and bluetooth module. 
*/ 
#include <SoftwareSerial.h> 

int bluetoothTx = 2; // TX-O pin of bluetooth mate, Arduino D2 
int bluetoothRx = 3; // RX-I pin of bluetooth mate, Arduino D3 

SoftwareSerial bluetooth(bluetoothTx, bluetoothRx); 

void setup() 
{ 

    bluetooth.begin(115200); // The Bluetooth Mate defaults to 115200bps 
    bluetooth.print("$"); // Print three times individually 
    bluetooth.print("$"); 
    bluetooth.print("$"); // Enter command mode 
    delay(100); // Short delay, wait for the Mate to send back CMD 
    bluetooth.println("U,9600,N"); // Temporarily Change the baudrate to 9600, no parity 
    // 115200 can be too fast at times for NewSoftSerial to relay the data reliably 
    bluetooth.begin(9600); // Start bluetooth serial at 9600 
} 

void loop() 
{ 
    String textToSend = "abcdefghijklmnopqrstuvw123456789"; 
    bluetooth.print(textToSend); 
    delay(5000); 
}