Как рекурсивно расширить переменную окружения?

Question

Предположим следующее:

echo %MY_ENV_VAR% расширяется %USERPROFILE%\some\path
echo %USERPROFILE% расширяется C:\Users\MyUser

Моя цель состоит в том, чтобы создать пустой файл по следующему пути: C:\Users\MyUser\some\path\FOO.txt.

Я попробовал следующую команду: type nul > %MY_ENV_VAR%\FOO.txt

К сожалению, выход есть ошибка, которая заявляет Система не может найти указанный путь.

Я довольно уверен, что это происходит потому, что оболочка не рекурсивно расширяется %MY_ENV_VAR% и он пытается найти буквальный путь, который начинается с %USERPROFILE%.

Как я могу достичь цели?

Answer 1

rem Create the problem 
set "MY_ENV_VAR=%%USERPROFILE%%\some\path" 
echo %MY_ENV_VAR% 

rem One solution 
call set "MY_ENV_VAR=%MY_ENV_VAR%" 
echo %MY_ENV_VAR% 

В call линии, анализатор заменит %MY_ENV_VAR% с содержанием переменной, генерируя

call set "MY_ENV_VAR=%USERPROFILE%\some\path" 

При выполнении этой команды, то call заставит второй этап синтаксического анализа, генерации

set "MY_ENV_VAR=C:\Users\MyUser\some\path" 

Конечно, если USERPROFILE содержит другую ссылку на переменную, процесс должен быть повторяется.

отредактировал - Добавлено «решение» для «рекурсивной» проблемы и поместило весь код внутри подпрограммы.

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    rem Create the problem 
    set "_1first=c:\users" 
    set "_2second=%%_1first%%\test" 
    set "_3third=%%_2second%%\so & me\path" 
    set "_4fourth=%%_3third%%" 

    set "MY_ENV_VAR=%%_4fourth%%" 

    echo inner variables 
    echo ----------------------------- 
    set _ 
    echo ----------------------------- 
    echo(

    echo "MY_ENV_VAR = [%MY_ENV_VAR%]" 
    call :expandInnerVariables MY_ENV_VAR 
    echo "MY_ENV_VAR = [%MY_ENV_VAR%]" 
    goto :eof 

:expandInnerVariables varName 
    setlocal enableextensions disabledelayedexpansion 
    set "aux==" 
    for /l %%i in (0 1 100) do (
     setlocal enabledelayedexpansion 
     if "!%~1!"=="" (
      endlocal & goto :endExpand 
     ) else for /f "delims=" %%a in ("=!%~1!") do (
      endlocal & call set "%~1%%a" 
      setlocal enabledelayedexpansion 
      for /f "delims=" %%b in ("=!%~1!") do (
       endlocal & set "aux=%%b" & if %%a==%%b goto :endExpand 
      ) 
     ) 
    ) 
    :endExpand 
    endlocal & set "%~1%aux%" 
    goto :eof