Синтаксис Haskell: значение {..} и @

Question

Я просто изучаю Йесод/Хаскелл.

В следующем коде (http://www.yesodweb.com/book/restful-content) есть две вещи, которые я не понимаю (и следующий вопрос).

1. {..} - Что это значит? (Это трудный термин для Google.)
2. person@Person - что делает знак @?
3. Есть ли способ найти ответы на ungoglable синтаксис Haskell, не беспокоя вас всех на StackOverflow?

код:

{-# LANGUAGE OverloadedStrings #-} 
{-# LANGUAGE QuasiQuotes  #-} 
{-# LANGUAGE RecordWildCards #-} 
{-# LANGUAGE TemplateHaskell #-} 
{-# LANGUAGE TypeFamilies  #-} 
import   Data.Text (Text) 
import   Yesod 

data Person = Person 
    { name :: Text 
    , age :: Int 
    } 

instance ToJSON Person where 
    toJSON Person {..} = object 
     [ "name" .= name 
     , "age" .= age 
     ] 

data App = App 

mkYesod "App" [parseRoutes| 
/HomeR GET 
|] 

instance Yesod App 

getHomeR :: Handler TypedContent 
getHomeR = selectRep $ do 
    provideRep $ return 
     [shamlet| 
      <p>Hello, my name is #{name} and I am #{age} years old. 
     |] 
    provideJson person 
    where 
    person@Person {..} = Person "Michael" 28 

main :: IO() 
main = warp 3000 App 

Answer 1

Для пунктов 1 и 2, я предполагаю, что вы имеете в виду линию

person@Person {..} 

{..} происходит от расширения RecordWildcards. В основном он охватывает все поля типа данных Person. Вот почему вы можете использовать name и age в шаблоне Гамлета выше.

@ служит в качестве псевдонима. Каждый раз, когда вы видите id@deconstructor_expr, вы можете использовать id для всего значения, которое деконструировано по deconstructor_expr. Например, вы можете иметь

f (x:a@(y:_)) = a 

и a будет tail из списка аргументов, пока список содержит по крайней мере 2 элемента (т.е. f является tail для списков с более чем 2-х элементов).

Без этих двух, вся функция должна измениться к

getHomeR :: Handler TypedContent 
getHomeR = selectRep $ do 
    provideRep $ return 
     [shamlet| 
      <p>Hello, my name is #{name'} and I am #{age'} years old. 
     |] 
    provideJson person 
    where 
    person = Person "Michael" 28 
    name' = name person 
    age' = age person 

Заметим, что name и age являются функциями от записи к конкретному полю, и это означает, что вы должны использовать другие имена для значений (переменные-переменные '). Кроме того, поскольку мы больше не используем @, нам нужны отдельные строки для person и для полей.

Другой альтернативой было бы

getHomeR :: Handler TypedContent 
getHomeR = selectRep $ do 
    provideRep $ return 
     [shamlet| 
      <p>Hello, my name is #{name person} and I am #{age person} years old. 
     |] 
    provideJson person 
    where 
    person = Person "Michael" 28 

Вам все еще нужно вызвать name и age функции.

Для пункта 3 возможно перейти на IRC на #haskell и спросить там. Во всяком случае, те же люди оттуда здесь, это не беспокойство в вопросе.

Answer 2

{..} распаковывает запись в переменные. В вашем случае он определяет name и age. @ принимает все значение в соответствии с шаблоном, поэтому в person@Person {..}, person будет оригинальным значением Person.

Answer 3

Добавление к другим ответам для поиска синтаксиса ungooglable symbolhound.com.