XSLT Разделить дочерние элементы на новые узлы

Question

Мне нужно преобразовать структуру XML-файла, а фигурируемый XSLT может быть лучшим решением (это то, для чего это правильно?) У меня есть некоторый опыт работы с XSLT, но он немного ограничен, поэтому мне нужно немного руководство.

Сценарий выглядит следующим образом; У меня есть XML, содержащий одну или несколько записей. Каждая запись имеет набор полей, и каждое поле имеет набор подполей. Порядок вспомогательных полей значителен. Что нужно сделать, так это то, что входная структура должна быть преобразована так, чтобы каждое возникновение кодов подполя A и K приводило к появлению нового поля (с новым кодом и подполем K, переименованным в A) на выходе с подпунктом поля, которые следует за подполем A или K, как показано в примере ниже. Количество подполей K произвольно и может отличаться от записи, чтобы записать xslt, чтобы быть немного общим.

Вот мой вход XML:

<?xml version="1.0" encoding="UTF-8" ?> 
    <record> 
     <field code="123"> 
     <subfield code="A">Abc</subfield> 
     <subfield code="B">De</subfield> 
     <subfield code="K">Fgh</subfield> 
     <subfield code="C">IJ</subfield> 
     <subfield code="K">Klmn</subfield> 
     <subfield code="D">OP</subfield> 
    </field> 
    <field>... more datafields... </field> 
    </record> 

Нужный выход следующим образом:

<?xml version="1.0" encoding="UTF-8" ?> 
    <record> 
     <field code="124"> 
     <subfield code="A">Abc</subfield> 
     <subfield code="B">De</subfield> 
    </field> 
    <field code="124"> 
     <subfield code="A">Fgh</subfield> 
     <subfield code="C">IJ</subfield> 
    </field> 
    <field code="124"> 
     <subfield code="A">Klmn</subfield> 
     <subfield code="D">OP</subfield> 
    </field> 
    <field>... more datafields... </field> 
    </record> 

Если кто-нибудь может дать мне какой-то образец XSLT, что по крайней мере указывает меня в правильном направлении, я я был бы очень обязан.

EDIT: Просто уточнить. Между подполями A и K может быть любое количество подполей.

Answer 1

Предполагая, что процессор XSLT 2.0, как Saxon 9 или Altova или XmlPrime вы можете использовать

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"> 

<xsl:strip-space elements="*"/> 

<xsl:output indent="yes"/> 

<xsl:template match="@* | node()"> 
    <xsl:copy> 
    <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="field"> 
    <xsl:for-each-group select="subfield" group-starting-with="subfield[@code = ('A', 'K')]"> 
    <field code="124"> 
     <xsl:apply-templates select="current-group()"/> 
    </field> 
    </xsl:for-each-group> 
</xsl:template> 

<xsl:template match="subfield/@code[. = 'K']"> 
    <xsl:attribute name="{name()}" select="'A'"/> 
</xsl:template> 

</xsl:stylesheet> 

, который превращает

<?xml version="1.0" encoding="UTF-8" ?> 
    <record> 
     <field code="123"> 
     <subfield code="A">Abc</subfield> 
     <subfield code="B">De</subfield> 
     <subfield code="K">Fgh</subfield> 
     <subfield code="C">IJ</subfield> 
     <subfield code="K">Klmn</subfield> 
     <subfield code="D">OP</subfield> 
    </field> 
    <field>... more datafields... </field> 
    </record> 

в

<record> 
    <field code="124"> 
     <subfield code="A">Abc</subfield> 
     <subfield code="B">De</subfield> 
    </field> 
    <field code="124"> 
     <subfield code="A">Fgh</subfield> 
     <subfield code="C">IJ</subfield> 
    </field> 
    <field code="124"> 
     <subfield code="A">Klmn</subfield> 
     <subfield code="D">OP</subfield> 
    </field> 
</record> 

Если вам нужен Решение XSLT 1.0 затем

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 

<xsl:strip-space elements="*"/> 

<xsl:output indent="yes"/> 

<xsl:key name="sub" match="subfield[not(@code = 'A' or @code = 'K')]" 
    use="generate-id(preceding-sibling::subfield[@code = 'A' or @code = 'K'][1])"/> 

<xsl:template match="@* | node()"> 
    <xsl:copy> 
    <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="field"> 
    <xsl:apply-templates select="subfield[@code = 'A' or @code = 'K']" mode="group"/> 
</xsl:template> 

<xsl:template match="subfield[@code = 'A' or @code = 'K']" mode="group"> 
    <field code="124"> 
    <xsl:apply-templates select=". | key('sub', generate-id())"/> 
    </field> 
</xsl:template> 

<xsl:template match="subfield/@code[. = 'K']"> 
    <xsl:attribute name="{name()}">A</xsl:attribute> 
</xsl:template> 

</xsl:stylesheet> 

следует делать.

Answer 2

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

<xsl:template match="subfield"> 
    <field code="{../@code}"> 
     <xsl:copy-of select="." /> 
     <xsl:copy-of select="following-sibling::subfield[1]" /> 
    </field> 
</xsl:template> 

<xsl:template match="record"> 
    <xsl:apply-templates select="//subfield[position() mod 2 = 1]" /> 
</xsl:template> 

<xsl:template match="/"> 
    <xsl:apply-templates select="record" /> 
</xsl:template> 

</xsl:stylesheet>