Выделите переменную под курсором в Vim, как в NetBeans

Question

Я работал в NetBeans и мне понравилась эта функция: при размещении курсора в имени переменной выделяются все вхождения переменной. Это очень полезно для быстрого поиска всех вступлений переменной. Можно ли добавить это поведение к Vim?

Answer 1

Это автокомандный будет делать то, что вы хотите:

:autocmd CursorMoved * exe printf('match IncSearch /\V\<%s\>/', escape(expand('<cword>'), '/\')) 

Edit: Я использовал группу IncSearch выделения в моем примере, но вы можете найти другие цвета использовать, запустив этот команда:

:so $VIMRUNTIME/syntax/hitest.vim 

Answer 2

Если вы установили

:set hlsearch 

, чтобы выделить все вхождения шаблона поиска, а затем использовать * или # найти вхождения слова под курсором, которая поможет вам каким-то образом к тому, что вы хотите. Однако я думаю, что подсветка переменных с поддержкой синтаксиса выходит за рамки VIM.

Answer 3

Я думаю, что вам действительно нужен следующий плагин Shuhei Kubota:

http://www.vim.org/scripts/script.php?script_id=4306

Согласно описанию: "Этот скрипт выделяет слова под курсором, как и многие Иды.

Cheers.

Answer 4

Это заявление позволит переменной для включения/выключения подсветки всех вхождений слова под курсором:

:autocmd CursorMoved * exe exists("HlUnderCursor")?HlUnderCursor?printf('match IncSearch /\V\<%s\>/', escape(expand('<cword>'), '/\')):'match none':"" 

Можно было бы активировать выделение с:

:let HlUnderCursor=1 

и отключить его:

:let HlUnderCursor=0 

Можно легко определить комбинацию клавиш для включения/отключения нг подсветка:

:nnoremap <silent> <F3> :exe "let HlUnderCursor=exists(\"HlUnderCursor\")?HlUnderCursor*-1+1:1"<CR> 

Удаление переменной будет препятствовать заявление матча от исполнения, и не ясно, текущее выделение:

:unlet HlUnderCursor 

Answer 5

Если вы не хотите, чтобы выделить языковые слова (заявления/preprocs, такие как if, #define), когда курсор находится над этими словами, вы можете поместить эту функцию в .vimrc на основе @too_much_php ответа:

let g:no_highlight_group_for_current_word=["Statement", "Comment", "Type", "PreProc"] 
function s:HighlightWordUnderCursor() 
    let l:syntaxgroup = synIDattr(synIDtrans(synID(line("."), stridx(getline("."), expand('<cword>')) + 1, 1)), "name") 

    if (index(g:no_highlight_group_for_current_word, l:syntaxgroup) == -1) 
     exe printf('match IncSearch /\V\<%s\>/', escape(expand('<cword>'), '/\')) 
    else 
     exe 'match IncSearch /\V\<\>/' 
    endif 
endfunction 

autocmd CursorMoved * call s:HighlightWordUnderCursor()