Установка даты NULL

Question

У меня есть поле даты в моей базе данных, которое устанавливается, когда клиент настроен на неактивность, когда пользователь нажимает кнопку, чтобы отключить их. У меня возникли проблемы с попыткой выяснить, как очистить неактивную дату, когда пользователь пытается реагировать на клиента.

Это то, что код кнопки Деактивировать выглядит следующим образом:

Private Sub btnDeactivate_Click(sender As System.Object, e As EventArgs) Handles btnDeactivate.Click 
     Dim selectedCustomers = GetSelectedCustomers() 
     Dim newInActiveFlag = Not selectedCustomers.Any(Function(c) (c.Inactive_Flag = "Y")) 
     Dim activateWord = "Activate" 
     If newInActiveFlag Then 
      activateWord = "Deactivate" 
     End If 

     Dim result As DialogResult = MessageBox.Show(String.Format("Are you sure you want to {0} this Customer?", activateWord.ToLower()), activateWord + " Customer", _ 
                MessageBoxButtons.YesNo, MessageBoxIcon.Question) 
     If result = Windows.Forms.DialogResult.Yes Then 

      Dim selectedCustomerIds = selectedCustomers.Select(Function(c) (c.Cust_Num)) 

      Dim service = New DataService() 

      service.Customers.SetInactiveFlags(selectedCustomerIds, newInActiveFlag) 
      service.SaveChanges() 
      PerformSearch(_lastSearchTxt, _lastIncludeActive) 
     End If 
    End Sub 

Вот часть, где он устанавливает неактивный флаг и дата:

Public Sub SetInactiveFlags(custIds As IEnumerable(Of Integer), inactiveFlag As Boolean) 
     Dim customers As List(Of Customer) 
     customers = _context.Customers.Where(Function(c) (custIds.Contains(c.Cust_Num))).ToList() 

     For Each customer As Customer In customers 
      customer.Inactive_Flag = CreateFromBoolean(inactiveFlag) 
      customer.Inactive_Date = DateTime.Today 
     Next 

    End Sub 

Можно ли иметь один и тот же набор кнопок и удалить дату так же, как я установил ее и удалить флаг неактивности?

благодаря

Answer 1

Предположив вы позволяете null значения на вашем Inactive_Date поле, вы можете просто установить его в настоящее время. Если вы измените метод SetInactiveFlags иметь Nullable (Of DateTime) параметра (? Или ярлык его с DateTime ала C#), вы можете передать его через непосредственно:

Public Sub SetInactiveFlags(custIds As IEnumerable(Of Integer), inactiveDate As DateTime?, inactiveFlag As Boolean) 
... 
customer.Inactive_Date = inactiveDate 
... 

Затем вы можете использовать SetInactiveFlags(selectedCustomerIds, Nothing, newInActiveFlag) или SetInactiveFlags(selectedCustomerIds, DateTime.Now, newInActiveFlag)

Сущность framework/Linq2Sql автоматически преобразует Nothing в DBNull.Value.

Answer 2

Хорошо, я думаю, я нашел решение, я принял совет Тома и добавил это событие БТН клик:

If activateWord = "Deactivate" Then 
       service.Customers.SetInactiveFlags(selectedCustomerIds, DateTime.Today, newInActiveFlag) 
      ElseIf activateWord = "Activate" Then 
       service.Customers.SetInactiveFlags(selectedCustomerIds, Nothing, newInActiveFlag) 
      End If 

поэтому полный кусок выглядит следующим образом:

Private Sub btnDeactivate_Click(sender As System.Object, e As EventArgs) Handles btnDeactivate.Click 
     Dim selectedCustomers = GetSelectedCustomers() 
     Dim newInActiveFlag = Not selectedCustomers.Any(Function(c) (c.Inactive_Flag = "Y")) 
     Dim activateWord = "Activate" 
     If newInActiveFlag Then 
      activateWord = "Deactivate" 
     End If 

     Dim result As DialogResult = MessageBox.Show(String.Format("Are you sure you want to {0} this Customer?", activateWord.ToLower()), activateWord + " Customer", _ 
                MessageBoxButtons.YesNo, MessageBoxIcon.Question) 
     If result = Windows.Forms.DialogResult.Yes Then 

      Dim selectedCustomerIds = selectedCustomers.Select(Function(c) (c.Cust_Num)) 

      Dim service = New DataService() 
      If activateWord = "Deactivate" Then 
       service.Customers.SetInactiveFlags(selectedCustomerIds, DateTime.Today, newInActiveFlag) 
      ElseIf activateWord = "Activate" Then 
       service.Customers.SetInactiveFlags(selectedCustomerIds, Nothing, newInActiveFlag) 
      End If 
      service.SaveChanges() 
      PerformSearch(_lastSearchTxt, _lastIncludeActive) 
     End If 
    End Sub 

Я также изменил SetInactiveFlags выглядит так:

Public Sub SetInactiveFlags(custIds As IEnumerable(Of Integer), Inactive_Date As DateTime?, inactiveFlag As Boolean) 
     Dim customers As List(Of Customer) 
     customers = _context.Customers.Where(Function(c) (custIds.Contains(c.Cust_Num))).ToList() 

     For Each customer As Customer In customers 
      customer.Inactive_Flag = CreateFromBoolean(inactiveFlag) 
      customer.Inactive_Date = Inactive_Date 
     Next 

    End Sub 

Я взял минутку, чтобы понять логику, но спасибо за takin g время, чтобы помочь мне, я действительно ценю это.