Проверка наличия столбца в таблице базы данных

Question

Я использую следующий код, чтобы проверить, существует ли столбец, когда он не создается.

<cfquery name="qSelect" datasource="#dbname#"> 
    select Top 0 * from Elements 
</cfquery> 

<cfif not ListFindNoCase(qSelect.columnlist,"idLang")> 
    <cfquery name="qAlterTable" datasource="#dbname#" dbtype="ODBC"> 
     ALTER TABLE Elements ADD idLang varchar(200) NULL 
    </cfquery> 
</cfif> 

Может кто-нибудь предложить, если есть лучший способ сделать это?

Answer 1

Я бы запросил information_schema напрямую.

SELECT COLUMN_NAME 
FROM INFORMATION_SCHEMA.COLUMNS 
WHERE TABLE_NAME = 'YourTableName' 
AND COLUMN_NAME = 'idLang' 

Если вы проверяете несколько имен столбцов можно изменить = к IN, а затем выполнять те же проверки, что вы делаете сейчас (listFindNoCASE). Я не знаю, что в любом случае это будет быстрее/лучше, но я так и сделаю.

Вы не указали СУБД, но это будет работать для SQL Server и MySQL

Answer 2

ответ Мэтта лучше.

Если вы не хотите, чтобы проверить первый или вы используете удивительный DB, как JET, вы также можете просто обернуть запрос в <cftry> теги

<cftry> 
    <cfquery name="qAlterTable" datasource="#dbname#" dbtype="ODBC"> 
     ALTER TABLE 
      Elements 
     ADD idLang varchar(200) NULL 
    </cfquery> 
    <cfcatch type = "database"> 
     <cfoutput>#cfcatch.message# - #cfcatch.details#</cfoutput> 
    </cfcatch> 
</try> 

Answer 3

Если у вас есть ColdFusion 8+, лучший способ использовать <cfdbinfo>. Затем вы можете использовать его с любой базой данных.

<cfdbinfo datasource="votethisway.com" name="myColumns" type="columns" table="tblPoll" pattern="idLang"> 
<cfdump var="#myColumns#" label="myColumns"> 

<cfdbinfo> возвращает объект запроса, который содержит всю информацию о каждом столбце в таблице. Атрибут pattern может использоваться как фильтр для уменьшения результатов только для столбца, который вы тестируете.

Вот <cffunction>, который оборачивает его в красивую упаковку:

<cffunction access="public" name="tableColumnExists" output="no" returntype="boolean" description="returns true if a table column exists" verifyclient="no" securejson="false"> 
    <cfargument name="datasource" type="string" required="yes" hint="name of the datasource"> 
    <cfargument name="table" type="string" required="yes" hint="name of the table"> 
    <cfargument name="column" type="string" required="yes" hint="name of the column"> 

    <!---initialize private variables---> 
    <cfset var local = StructNew()> 

    <cftry> 
     <cfdbinfo datasource="#arguments.datasource#" name="local.qryColumns" type="columns" table="#arguments.table#" pattern="#arguments.column#"> 
     <cfcatch type="Database"> 
      <cfreturn false> 
     </cfcatch> 
    </cftry> 

    <cfif local.qryColumns.RecordCount> 
     <cfreturn true> 
    </cfif> 
    <cfreturn false> 
</cffunction> 

Answer 4

Итак, я последовал каждое предложение в этом диалоге, и каждый из них был другой орех, чтобы связать. Затем я провел еще 3 часа в Интернете и до сих пор не придумал ПРОСТОЕ РЕШЕНИЕ к этой проблеме.

Зная, что coldfusion является простым серверным языком, я знаю, что где-то был какой-то ответ, поэтому я попробовал функцию «columnList». Удивительно, но это сработало:

---

<cfquery name="my_Recordset" datasource="my_Datasource"> 
    SELECT * FROM my_Table 
</cfquery> 

<CFIF NOT ISDEFINED('my_Recordset.my_Column')> 
    <!--- create column because it doesnt exist ---> 
<cfelse> 
    <!--- drop or update column because it exist ---> 
</cfif> 

---

Кроме того, вы можете поместить все столбцы в таблице в списке, вы можете выполнить поиск с помощью функции Список, ListContains, как показано ниже:

---

<cfquery name="my_Recordset" datasource="my_Datasource"> 
    SELECT * FROM my_Table 
</cfquery> 

<cfset myList = #my_Recordset.columnList#> 

<cfset mySearchResult = #ListContains(myList, "my_Column")#> 

<CFIF mySearchResult is 0> 
    <!--- create column because it doesnt exist ---> 
<cfelse> 
    <!--- drop or update column because it exist ---> 
</cfif> 

---