Преобразование даты в AWK

Question

У меня есть файл, содержащий много столбцов текста, включая метку времени по линиям Fri Jan 02 18:23, и мне нужно преобразовать эту дату в формат MM/DD/YYYY HH:MM.

Я пытаюсь использовать стандартный инструмент «date» с awk getline для преобразования, но я не могу понять, как передать поля в команду «date» в ожидаемом формате (цитируется с "или«с,) как GetLine нуждается в командной строке, заключенный в кавычки тоже.

что-то вроде "date -d '$1 $2 $3 $4' +'%D %H:%M'" | getline var

Теперь, когда я думаю об этом, я думаю, что я действительно спрашиваю, как вставлять AWK переменные в строку.

Answer 1

вы можете попробовать это. Предполагая, что указанная вами дата указана в файле

awk ' 
{ 
    cmd ="date \"+%m/%d/%Y %H:%M\" -d \""$1" "$2" "$3" "$4"\"" 
    cmd | getline var 
    print var 
    close(cmd) 
}' file 

выход

$ ./shell.sh 
01/02/2010 18:23 

и если вы не используете инструменты GNU, как если вы находитесь в Solaris, например, использовать nawk

nawk 'BEGIN{ 
    m=split("Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec",d,"|") 
    for(o=1;o<=m;o++){ 
     months[d[o]]=sprintf("%02d",o) 
    } 
    cmd="date +%Y" 
    cmd|getline yr 
    close(cmd) 
} 
{ 
    day=$3 
    mth=months[$2] 
    print mth"/"day"/"yr" "$4 
} ' file 

Answer 2

Если вы используете Gawk, вы не требуется внешний date, который может быть expensive для повторного вызова:

awk ' 
BEGIN{ 
    m=split("Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec",d,"|") 
    for(o=1;o<=m;o++){ 
     months[d[o]]=sprintf("%02d",o) 
    } 
format = "%m/%d/%Y %H:%M" 
} 
{ 
split($4,time,":") 
date = (strftime("%Y") " " months[$2] " " $3 " " time[1] " " time[2] " 0") 
print strftime(format, mktime(date)) 
}' 

ghostdog74 для массива месяцев от this answer.