итерация над перечислениями в perl

Question

Я пытаюсь создать (автоматически) массив каждый раз, когда создаю перечисление. Для этого я посылаю нужный массив перечислений через sub (myenum), который сначала создает массив, а затем вызывает enum (через использование).

В приведенном ниже примере у меня есть две перечисления, одна прямая, одна с указанным выше методом. Мой метод не работает :-(Что я делаю неправильно?

@enumArray=(); 

sub myenum($) 
{ 
    my @a = split (/\s+/,$_[0]); 
    my $prefix = $a[0]; 
    $prefix =~ s/^://; 
    my $len = scalar @a; 
    $len--; 
    my $i=0; 
    for ($i=1;$i<=$len;$i++) { 
    push (@enumArray, "$prefix.$a[$i]"); 
    } 
    use enum (@enumArray); 
} 

myenum(":THIS a=100 b c"); 

use enum qw(:THAT a=999 b c); 

print THISa . " " . THISb . " " . THISc . "\n"; 
print THATa . " " . THATb . " " . THATc . "\n"; 

Answer 1

use выполняет действие во время компиляции. В частности,

use enum qw(:THAT a=999 b c); 

эквивалентно

BEGIN { 
    require enum; 
    import enum qw(:THAT a=999 b c); 
} 

Это описано более подробно here.

Это значит, что вам нужно

BEGIN { 
    require enum; 
    import enum split ' ', ':THIS a=100 b c'; 
} 

или

use enum qw(); 
BEGIN { import enum split ' ', ':THIS a=100 b c'; } 

или

use enum qw(); 

sub myenum { 
    import enum split ' ', $_[0]; 
} 

BEGIN { myenum(':THIS a=100 b c') } 

Я предполагаю, что следующее не будет делать:

use enum split(' ', ':THIS a=100 b c'); 

Answer 2

Исследуя далее ответ @ Ikegami, я думаю, вот один из способов получить то, что вам нужно. Это связано с созданием нового пакета myenum, который представляет собой простую оболочку над enum, которая также поддерживает массив перечислений.

myenum.pm:

package myenum; 

use strict; 
use warnings; 

use enum; 

# array with all enums 
our @enums; 

sub import { 
    my $prefix = ''; 

    # basic parsing like what enum does 
    for my $name (@_[1..$#_]) { 
     if (substr($name, 0, 1) eq ':') { 
      $prefix = substr($name, 1); 
      next; 
     } 
     # add the enums to the array 
     push @enums, $prefix . $name; 
    } 

    # call enum's import() as if it was called from the current caller 
    goto &enum::import; 
} 

1; 

Основная программа:

use strict; 
use warnings; 

use myenum qw(:THAT a=999 b c); 

# this array has the enums 
print "@myenum::enums\n"; 

print THATa . " " . THATb . " " . THATc . "\n"; 

# output: 
# 
# THATa=999 THATb THATc 
# 999 1000 1001 

Примечание: Это только в основном скелет код, который я написал в качестве эксперимента, и вы, безусловно, необходимо внести изменения в соответствии с твои нужды. Тем более, что в новом редактировании вы сказали, что вам нужно делать обратный поиск.