Связывание данных между двумя листами на основе неравномерных диапазонов данных

Question

Я пытаюсь взять неравномерный диапазон данных на одном листе и связать его (ячейки будут иметь «= Sheet1! A1», а не жестко закодированные значения), чтобы другой рабочий лист в той же книге.

Я не могу использовать только .UsedRange потому что я получаю много пустых ячеек в мой выбор, который я не хочу сделать ссылку на другой лист

Вот мой код до сих пор, но я получаю сообщение об ошибке сказав вам не может использовать .copy с таким выбором. Может кто-нибудь попросит об этом. Спасибо.

Sub test() 
Application.ScreenUpdating = False 


ActiveSheet.UsedRange.SpecialCells(xlCellTypeConstants).Copy 
With Sheets("Sheet2") 
    .Activate 
    .Range("A1").Select 
    ActiveSheet.Paste Link:=True 
End With 


Application.CutCopyMode = False 
Application.ScreenUpdating = True 
End Sub 

Answer 1

Вы можете перебрать ячейки SpecialCells диапазонов по клетке, и писать ссылки на основе адреса источника клеток, как этот

Sub test() 
    Dim cl As Range 
    Dim sh As Worksheet 
    Dim ShName As String 
    Dim OldCalc As XlCalculation 

    Application.ScreenUpdating = False 
    OldCalc = Application.Calculation 
    Application.Calculation = xlCalculationManual 

    Set sh = Worksheets("Sheet2") 
    sh.Cells.Clear '<-- Optional 
    ShName = "='" & ActiveSheet.Name & "'!" 
    For Each cl In ActiveSheet.UsedRange.SpecialCells(xlCellTypeConstants) 
     sh.Range(cl.Address).Formula = ShName & cl.Address 
    Next 

    Application.ScreenUpdating = True 
    Application.Calculation = OldCalc 
End Sub 

В то время как цикл в диапазоне не является идеальным (из-за скорости), в этом случае он может быть адекватным.

Это Sub будет ошибка, если активный лист пуст: вы можете добавить обработчик ошибок для этого случая