AWK: Как печатать средние числа последовательных номеров в файле, но пропускать алфавитные символы/строки?

Question

Я понял, как получить среднее файл, который содержит номера во всех линиях, таких как:

Numbers.txt

1 

2 

4 

8 

Выход:

Average: 3.75 

Это код, который я использую для этого:

awk '{ sum += $1; tot++ } END { print sum/tot; }' Numbers.txt 

Однако проблема заключается в том, что это не учитывает возможные строки, которые могут быть в файле. Например, файл, который выглядит следующим образом:

NumbersAndExtras.txt

1 

2 

4 

8 

Hello 

4 

5 

6 

Cat 

Dog 

2 

4 

3 

Для такого файла я хочу, чтобы напечатать несколько средних значений последовательных чисел, не обращая внимания на такие строки, что результат выглядит примерно так:

Выход:

Average: 3.75 

Average: 5 

Average: 3 

я мог придумать какой-то сложный код, может сделать это с помощью переменных и «if» операторов и циклов и еще много чего, но мне сказали, что это проще, чем при некоторых функциях awk. Я хотел бы знать, как это может выглядеть, а также объяснение того, почему это работает.

Answer 1

BEGIN запускается перед чтением первой строки из файла. Задайте сумму и количество 0.

awk 'BEGIN{ sum=0; count=0} {if (/[a-z][A-Z]/) { if (count > 0) {avg = sum/count; print avg;} count=0; sum=0} else { count++; sum += $1} } END{if (count > 0) {avg = sum/count; print avg}} ' NumbersAndExtras.txt 

Когда на линии есть алфавит, рассчитывайте и печатайте среднее значение.

И сделайте то же самое в блоке END, который запускается после обработки всего файла.

Answer 2

Примечание: значение этого ответа в объясняет решение; другие ответы предлагают более лаконичные альтернативы.

---

Попробуйте следующее:

^{Обратите внимание, что это awkкоманда со сценарием, указанным в строке оболочки с многострочных буквальные - вы можете вставить все это в ваш терминала попробуй; в то время как можно втиснуть это в одну линию, это больно читаемость и способность комментировать:}

awk ' 

# Define output function that prints an average. 
function printAvg() { print "Average: ", sum/count } 

# Skip blank lines 
NF == 0 { next}  

# Is the line non-numeric? 
/[[:alpha:]]/ { 
    # If this line ends a numeric block, print its 
    # average now and reset the variables to start the next group. 
    if (count) { 
     printAvg() 
     wasNum = sum = count = 0 
    } 
    # Skip to next line. 
    next 
    } 

    # Numeric line: set flag, sum, and increment counter. 
    { sum += $1; count++ } 

    # Finally: 
    END { 
    # If there is a group whose average has not been printed yet, 
    # do it now. 
    if (count) printAvg() 
    } 

' NumbersAndExtras.txt 

Если мы конденсироваться пропуски и полосы комментариев, мы до сих пор получить достаточно читаемый решение, до тех пор, мы по-прежнему использовать несколько строк:

awk ' 
function printAvg() { print "Average: ", sum/count } 
NF == 0 { next}  
/[[:alpha:]]/ { if (count) { printAvg(); sum = count = 0 } next } 
{ sum += $1; count++ } 
END { if (count) printAvg() } 
' NumbersAndExtras.txt 

Answer 3

еще один:

$ awk ' 
    function avg(s, c) { print "Average: ", s/c } 
    NF && !/^[[:digit:]]/ { if (count) avg(sum, count); sum = 0; count = 0; next} 
    NF { sum += $1; count++ } 
    END {if (count) avg(sum, count)} 
' <file 

Answer 4

Держите его простой:

awk '/^$/{next} 
    /^[0-9]+/{a+=$1+0;c++;next} 
    c&&a{print "Average: "a/c;a=c=0} 
    END{if(c&&a){print "Average: "a/c}}' input_file 

Результаты:

Average: 3.75 
Average: 5 
Average: 3