Пакетный цикл через файл

Question

Я пытаюсь выполнить пакетный процесс в Notepad ++, который будет подсчитывать количество повторяющихся строк из выбранного текста.

До сих пор у меня есть Notepad ++ работает отлично

NPE_CONSOLE v+ 
CLS 
ECHO $(CURRENT_WORD) 
CON_SAVETO "H:\tmp.txt" 
NPE_CONSOLE v- 

This сценарии сохраняет выбранный текст в tmp.txt с единственной проблемой является она включает в себя, в нижней части, CON_SAVETO "H:\tmp.txt", но я могу жить с этим на данный момент.

EDIT: Кроме того, я не думаю, что Notepad ++ это вопрос здесь, так как я пытаюсь запустить пакетный файл из cmd линии и получить те же ошибки/проблемы. Я также попытался установить файл tmp.txt вручную и все те же проблемы.

Мой командный файл является то, что вызывает вопросы:

::@ECHO OFF 
CD "H:\" 
SET counter=0 
SET prev=a 

FOR /F "tokens=*" %%L IN (tmp.txt) DO (
    SET blnOut=0 
    SET curLine="%%L" 

    IF /I %prev%==%curLine% (
     SET counter=%counter%+1 
     SET blnOut=1 
    ) 
    IF %blnOut%==0 (
     IF %prev%==a (
      SET counter=%counter%+1 
      SET blnOut=1 
     ) 
     IF %blnOut%==0 (
      ECHO %curLine%- %counter% 
      SET counter=1 
     ) 
    ) 
    SET prev=%curLine% 
) 

Я пробовал все, что я могу думать, в том числе откола процесса в функцию, но я продолжаю получать ошибки как Unexpected) или, если это выполняется, он не прокручивает файл.

В настоящее время это tmp.txt:

1 
2 
3 
4 
5 
6 
7 
8 
1 
4 
5 
8 
4 
3 
4 
4 
5 

Так Ideal выход:

1 - 2 
2 - 1 
3 - 2 
4 - 5 
5 - 3 
6 - 1 
7 - 1 
8 - 2 

Answer 1

@ECHO OFF 
SETLOCAL enabledelayedexpansion 
FOR %%i IN (prev) DO SET "%%i=" 
FOR /f "delims=" %%i IN ('sort ^<temp.txt') DO (
IF DEFINED prev (
    IF "!prev!"=="%%i" (SET /a count+=1) ELSE (
    ECHO !prev! - !count! 
    SET "prev=" 
) 
) 
IF NOT DEFINED prev (
    SET prev=%%i 
    SET /a count=1 
) 
) 
ECHO %prev% - %count% 

Вот моя версия. Сортируйте входной файл, чтобы группировать подобные строки вместе, а затем, когда содержимое строки изменяется, отображает предыдущее содержимое и подсчитывает и перезаписывает счетчик и записывает предыдущую строку.

Answer 2

Вы не можете установить переменную среды и использовать его в той же for цикла с использованием % синтаксиса, вы необходимо использовать задержанное расширение и использовать синтаксис !.

Я не проверял, но попробовать это:

::@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION 
CD "H:\" 
SET counter=0 
SET prev=a 

FOR /F "tokens=*" %%L IN (tmp.txt) DO (
    SET blnOut=0 
    SET curLine="%%L" 

    IF /I !prev!==!curLine! (
     SET counter=!counter!+1 
     SET blnOut=1 
    ) 
    IF !blnOut!==0 (
     IF !prev!==a (
      SET counter=!counter!+1 
      SET blnOut=1 
     ) 
     IF !blnOut!==0 (
      ECHO !curLine!- !counter! 
      SET counter=1 
     ) 
    ) 
    SET prev=!curLine! 
) 

Или переместить тело цикла for в подпрограмму.

Answer 3

Вы сделали больше ошибок, я бы сказал сейчас. Посмотрите на delayed expansion, if /?, for /?, set /? и все прочее ... пакетном

@ECHO OFF &setlocal enabledelayedexpansion 
CD /d "H:\" 
SET counter=0 
SET prev=a 

FOR /F "tokens=*" %%L IN (tmp.txt) DO (
    SET blnOut=0 
    SET "curLine=%%L" 

    IF /I "!prev!"=="!curLine!" (
     SET /a counter+=1 
     SET blnOut=1 
    ) 
    IF "!blnOut!"=="0" (
     IF "!prev!"=="a" (
      SET /a counter+=1 
      SET blnOut=1 
     ) 
     IF "!lnOut!"=="0" (
      ECHO !curLine!- !counter! 
      SET counter=1 
     ) 
    ) 
    SET "prev=!curLine!" 
) 

Ваш код не имеет смысла, если вы postet содержание tmp.txt правильно.

Answer 4

Вот моя идея для немного другого направления. Он выводит ожидаемые результаты. Выход не сортируется; сохраняется исходный порядок строк.

@ECHO OFF 
setlocal enabledelayedexpansion 

set filename=h:\tmp.txt 
set idx=0 

:: build array of unique lines 
FOR /F "usebackq delims=" %%I IN ("%filename%") DO (

    rem :: if dupe line not already processed 
    2>NUL set line | findstr /r /c:"^line\[[0-9]*\]=%%I$" >NUL || (

     rem :: add it to the array 
     set "line[!idx!]=%%I" 
     set /a "idx+=1" 
    ) 
) 

:: For each unique line 
set /a "idx-=1" 
for /L %%I in (0,1,%idx%) do (

    rem :: Echo the line contents without a line break 
    set /p "=!line[%%I]! - "<NUL 

    rem :: use find /c to count the instances of that line. 
    findstr /b /e /c:"!line[%%I]!" "%filename%" | find /c "!line[%%I]!" 
) 

Answer 5

Пакетная программа ниже делать то, что вы хотите в более быстром способе, пока линии не содержат определенные специальные символы Batch:

@echo off 
setlocal EnableDelayedExpansion 
for /F "delims=" %%a in (tmp.txt) do (
    set /A "line[%%a]+=1" 
) 
for /F "tokens=2* delims=[]=" %%a in ('set line[') do (
    echo %%a - %%b 
) 

Answer 6

У меня есть другое, но простое решение для Вас.

Вы можете скачать GNU utilities for win32. Затем просто извлеките его. Это набор переносимых инструментов для Windows. Очень удобно.

Затем используйте программы sort и uniq. Вы можете найти их в

extracted_folder\usr\local\wbin\ 

, то вы можете просто сделать

sort original_file.txt | uniq --count > count.txt 

из окон command line. Вы найдете то, что вам нужно в count.txt

---

Убедитесь, что пути исправить или у вас есть извлеченная папка в path. Если не в пути, то сделайте что-то вроде

"C:\GNUWin_standalone\usr\local\wbin\sort.exe" original_file.txt | "C:\GNUWin_standalone\usr\local\wbin\uniq.exe" --count > count.txt