Groovy, выполняющий команды оболочки

Question

Groovy добавляет метод execute к String, чтобы сделать исполняемые оболочки довольно простыми;

println "ls".execute().text 

но если произошла ошибка, то результата не будет. Есть ли простой способ получить стандартную и стандартную ошибку? (кроме создания кучи кода для создания двух потоков для чтения обоих входных потоков, а затем с помощью родительского потока, чтобы дождаться их завершения, затем преобразовать строки обратно в текст?)

Было бы неплохо иметь что-то как;

def x = shellDo("ls /tmp/NoFile") 
println "out: ${x.out} err:${x.err}" 

Answer 1

Хорошо, решил это сам;

def sout = new StringBuilder(), serr = new StringBuilder() 
def proc = 'ls /badDir'.execute() 
proc.consumeProcessOutput(sout, serr) 
proc.waitForOrKill(1000) 
println "out> $sout err> $serr" 

дисплеи:

out> err> ls: cannot access /badDir: No such file or directory

Answer 2

"ls".execute() возвращает Process объект, поэтому "ls".execute().text работы. Вы должны просто прочитать поток ошибок, чтобы определить, были ли какие-либо ошибки.

Дополнительный метод на Process, который позволяет вам передать StringBuffer для извлечения текста: consumeProcessErrorStream(StringBuffer error).

Пример:

def proc = "ls".execute() 
def b = new StringBuffer() 
proc.consumeProcessErrorStream(b) 

println proc.text 
println b.toString() 

Answer 3

// a wrapper closure around executing a string         
// can take either a string or a list of strings (for arguments with spaces)  
// prints all output, complains and halts on error        
def runCommand = { strList -> 
    assert (strList instanceof String || 
      (strList instanceof List && strList.each{ it instanceof String }) \ 
) 
    def proc = strList.execute() 
    proc.in.eachLine { line -> println line } 
    proc.out.close() 
    proc.waitFor() 

    print "[INFO] (" 
    if(strList instanceof List) { 
    strList.each { print "${it} " } 
    } else { 
    print strList 
    } 
    println ")" 

    if (proc.exitValue()) { 
    println "gave the following error: " 
    println "[ERROR] ${proc.getErrorStream()}" 
    } 
    assert !proc.exitValue() 
} 

Answer 4

Чтобы добавить еще один важную информацию выше предоставленных ответов -

Для процесса

def proc = command.execute(); 

всегда пытаются использовать

def outputStream = new StringBuffer(); 
proc.waitForProcessOutput(outputStream, System.err) 
//proc.waitForProcessOutput(System.out, System.err) 

вместо

def output = proc.in.text; 

захватить выходы после выполнения команд в заводной, как последний блокирующий вызов (SO question for reason).

Answer 5

def exec = { encoding, execPath, execStr, execCommands -> 

def outputCatcher = new ByteArrayOutputStream() 
def errorCatcher = new ByteArrayOutputStream() 

def proc = execStr.execute(null, new File(execPath)) 
def inputCatcher = proc.outputStream 

execCommands.each { cm -> 
    inputCatcher.write(cm.getBytes(encoding)) 
    inputCatcher.flush() 
} 

proc.consumeProcessOutput(outputCatcher, errorCatcher) 
proc.waitFor() 

return [new String(outputCatcher.toByteArray(), encoding), new String(errorCatcher.toByteArray(), encoding)] 

} 

def out = exec("cp866", "C:\\Test", "cmd", ["cd..\n", "dir\n", "exit\n"]) 

println "OUT:\n" + out[0] 
println "ERR:\n" + out[1] 

Answer 6

Я нахожу это более идиоматическим:

def proc = "ls foo.txt doesnotexist.txt".execute() 
assert proc.in.text == "foo.txt\n" 
assert proc.err.text == "ls: doesnotexist.txt: No such file or directory\n" 

Как отмечает еще один пост, эти блокирующие вызовы, но так как мы хотим работать с выходными сигнала, это может быть необходимо.

Answer 7

command = "ls *" 

def execute_state=sh(returnStdout: true, script: command) 

но если провал команды процесс прекращается