Преобразование и сортировка разных форматов даты

Question

У меня есть задача преобразовать сгенерированный XML-файл, используя разные форматы дат в качестве критериев сортировки. Будучи новичком в XSLT, я задаюсь вопросом, можно ли использовать одно преобразование, унифицировать форматы даты и сортировать.

Пример для источника XML здесь:

<?xml version="1.0"?> 
<summary> 
    <incoming> 
     <delivery incDate="2013-11-08"/> 
    </incoming> 
    <outgoing> 
     <delivery outDate="20131108"/> 
    </outgoing> 
    <repairs> 
     <repair repairDate="2013-11-08 11:25:34"/> 
    </repairs> 
</summary> 

И это то, что я хочу добиться:

<?xml version="1.0"?> 
<summary> 
    <actions> 
     <action type="incoming" dateTime="2013-11-08 00:00:00"/> 
     <action type="repair" dateTime="2013-11-08 11:25:34"/> 
     <action type="outgoing" dateTime="2013-11-08 23:59:59"/> 
    </actions> 
</summary> 

Что я сделал?

1. Унифицировать все форматы дат.
2. Добавить время 00:00:00 для всех детей <incoming>.
3. Добавить время 23:59:59 для всех детей <outgoing>.
4. Добавить атрибут с именем родителя.
5. Сортировка по дате.

Answer 1

В XSLT 2.0 это довольно просто, как вы можете использовать два проход подход, первый генерировать требуемые выходы, а затем отсортировать их:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"> 

    <xsl:output method="xml" indent="yes" /> 

    <xsl:template match="/"> 
    <summary> 
     <actions> 
     <xsl:perform-sort> 
      <xsl:sort select="@dateTime" /> 
      <xsl:apply-templates select="summary/*/*" /> 
     </xsl:perform-sort> 
     </actions> 
    </summary> 
    </xsl:template> 

    <xsl:template match="incoming/delivery"> 
    <action type="incoming" dateTime="{@incDate} 00:00:00"/> 
    </xsl:template> 

    <xsl:template match="outgoing/delivery"> 
    <action type="outgoing" dateTime="{substring(@outDate, 1, 4)}-{substring(@outDate, 5, 2)}-{substring(@outDate, 7, 2)} 23:59:59"/> 
    </xsl:template> 

    <xsl:template match="repairs/repair"> 
    <action type="repair" dateTime="{@repairDate}"/> 
    </xsl:template> 
</xsl:stylesheet> 

Здесь мы генерирование выхода для каждого входа с использованием apply-templates и , затем, сортируя эти сгенерированные элементы с помощью perform-sort с использованием выражения XPath (@dateTime) относительно сгенерированного XML, а не оригинала.

Если вы ограничены 1.0, это не вариант, поскольку вы можете сортировать только на основе входных данных XML, а не сгенерированного вывода. Таким образом, мы должны придумать 1,0 выражения одного XPath, который может обрабатывать любого из трех форматов даты и произвести подходящий ключ сортировки

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 

    <xsl:output method="xml" indent="yes" /> 

    <xsl:template match="/"> 
    <summary> 
     <actions> 
     <xsl:apply-templates select="summary/*/*"> 
      <xsl:sort select=" 
      translate(
       concat(
       @incDate, @outDate, @repairDate, 
       substring('000000', 6*not(@incDate) + 1), 
       substring('235959', 6*not(@outDate) + 1) 
       ), 
       '-: ', 
       '' 
      )" /> 
     </xsl:apply-templates> 
     </actions> 
    </summary> 
    </xsl:template> 

    <!-- the other three templates are unchanged --> 

Это использует ряд трюков, прежде всего

substring('000000', 6*not(@incDate) + 1) 

которая опирается на целый ряд вещей:

• аргумент not() трактуется как логическое значение.
• когда вы лечите узел установлен как логическое значение, пустое множество является ложным и непустым множество истинно
• литья булева номера дает 1 для истинно и 0 для ложного

поэтому эффект для возврата строки 000000, если целевой узел имеет атрибут incDate, а пустую строку - нет. Окончательный concat создает строку, которая будет выглядеть как YYYY-MM-DD000000 для incDate, YYYYMMDD235959 для outDate и YYYY-MM-DD HH:mm:ss для repairDate, то translate обрезает все пробелы, дефис и колонов, чтобы привести эти три в общий формат, который можно сравнить лексически.