Excel VBA - удалить дубликаты в строке

Question

Друзья,

У меня есть таблица excel, которая повторяется для нескольких тысяч строк. 3 категории столбцов, которые могут повторяться, например, во второй строке, показанной ниже

Есть ли способ, чтобы цикл excel через строку удалял дубликаты внутри строки, так что это в конечном счете выглядит как вторая таблица, показанная ниже ниже?

Answer 1

Я не уверен, но это то, что вы пытаетесь?

Option Explicit 

Sub Sample() 
    Dim wsI As Worksheet 
    Dim lastRow As Long, lastCol As Long, i As Long, j As Long 
    Dim sVal1, sVal2, sVal3 

    '~~> Input Sheet 
    Set wsI = Sheets("Sheet1") 

    With wsI 
     lastRow = .Cells.Find(What:="*", After:=.Range("A1"), _ 
        Lookat:=xlPart, LookIn:=xlFormulas, SearchOrder:=xlByRows, _ 
        SearchDirection:=xlPrevious, MatchCase:=False).Row 

     lastCol = .Cells.Find(What:="*", After:=.Range("A1"), _ 
        Lookat:=xlPart, LookIn:=xlFormulas, SearchOrder:=xlByColumns, _ 
        SearchDirection:=xlPrevious, MatchCase:=False).Column 

     For i = 1 To lastRow 
      sVal1 = .Cells(i, 1).Value 
      sVal2 = .Cells(i, 2).Value 
      sVal3 = .Cells(i, 3).Value 

      For j = 4 To lastCol Step 3 
       If .Cells(i, j).Value = sVal1 And _ 
       .Cells(i, j + 1).Value = sVal2 And _ 
       .Cells(i, j + 2).Value = sVal3 Then 
        .Cells(i, j).ClearContents 
        .Cells(i, j + 1).ClearContents 
        .Cells(i, j + 2).ClearContents 
       End If 
      Next j 
     Next i 
    End With 
End Sub