Вложенные инструкции Exist в пакетном файле

Question

Хорошо, я пытаюсь сделать пару вложенных инструкций IF EXIST для проверки наличия пары папок. Если первая папка существует, установите Folder1 равным 1, а затем перейдите к Install. То же самое с Folder2, а затем, если ни одна из них не существует, просто пропустите, чтобы установить.

Но даже если Folder1 не существует, это все равно устанавливает% Folder1% равным 1. Что мне не хватает/не делает?

Спасибо!

if exist "c:\folder1" set Folder1=1 
    echo %Folder1% 
    goto install 
else if exist "c:\folder2" set Folder2=1 
    echo %Folder2% 
    goto Install 
else goto Install 

:Install 

Answer 1

две основные проблемы:

должно быть заключено в скобки Составной оператор. В круглых скобках изменение значения переменной НЕ будет видимым, ЕСЛИ вы не выполнили SETLOCAL ENABLEDELAYEDEXPANSION - и даже тогда вам нужно будет использовать! Var! не% Var%

Итак:

SETLOCAL ENABLEDELAYEDEXPANSION 
if exist "c:\folder1" (
     set Folder1=1 
     echo !Folder1! 
     goto install 
) else if exist "c:\folder2" (
     set Folder2=1 
     echo !Folder2! 
     goto Install 
) else goto Install 

:Install 

Или предпочтительно,

@ECHO off 
if exist "c:\folder1" (
     set Folder1=1 
     goto install 
) else if exist "c:\folder2" (
     set Folder2=1 
     goto Install 
) else goto Install 

:Install 

SET folder 

Или еще проще

@ECHO off 
if exist "c:\folder1" set Folder1=1&goto install 
if exist "c:\folder2" set Folder2=1&goto Install 
:Install 

SET folder 

---

Тест:

@ECHO OFF 
setlocal 
SET "folder1=" 
SET "folder2=" 
ECHO.----------No folders 
DIR /b /ad c:\folder* 
CALL :test 
ECHO.----------Folder 1 only 
MD c:\folder1 
DIR /b /ad c:\folder* 
CALL :test 
ECHO.----------Folder 2 only 
RD c:\folder1 
MD c:\folder2 
DIR /b /ad c:\folder* 
CALL :test 
ECHO.----------Both 
MD c:\folder1 
DIR /b /ad c:\folder* 
CALL :test 
RD c:\folder1 
RD c:\folder2 

GOTO :eof 

:test 
if exist "c:\folder1" set Folder1=1&goto install 
if exist "c:\folder2" set Folder2=1&goto Install 
:Install 

SET folder 
SET "folder1=" 
SET "folder2=" 
GOTO :eof 

Этот тест создает и удаляет указанные два каталога.

Вот результат:

----------No folders 
----------Folder 1 only 
folder1 
Folder1=1 
----------Folder 2 only 
folder2 
Folder2=1 
----------Both 
folder1 
folder2 
Folder1=1 

Обратите внимание, что

SET "folder1=" 
    SET "folder2=" 

который выполнен как в начале и после каждого отчета гарантирует, что переменные среды в вопросе удаляются из окружающей среды, чтобы предотвратить код, дающий ложные результаты по устаревшей информации.

Answer 2

if exist "c:\folder1" (
     set Folder1=1 
     echo %Folder1% 
     goto install 
) if exist "c:\folder2" (
     set Folder2=1 
     echo %Folder2% 
     goto Install 
) else goto Install 

:Install 

Answer 3

Этот код не устанавливает% folder1% = 1, если folder1 не существует, и в этом случае он не выводит результат. Если Folder1 не существует И Папка2 существует THEN% folder2% установлен в 1, в противном случае% folder2% пуст. Поместите незамкнутые левые круглые скобки после команды echo для подавления вывода, если переменная пуста.

@echo off &setlocal 
if exist "c:\folder1" set "Folder1=1" 
echo(%Folder1% 
if not defined Folder1 if exist "c:\folder2" set "Folder2=1" 
echo(%Folder2% 
goto Install 

:Install 
endlocal