Linq Join on Mutliple Properties

Question

Являются ли следующие два запроса функционально одинаковыми? Первый не возвращает никаких данных, но второй работает отлично с одинаковым точным вводом. Может кто-нибудь указать, что не так в моем первом запросе?

Dim LTest2 As IEnumerable = From e1 As QNCEntity In Shape.Entities _ 
         Join e2 As QNCEntity In Shape.Entities _ 
         On New With { _ 
            .X = CDbl(e1.EntObj.X2), _ 
            .Y = CDbl(e1.EntObj.Y2) _ 
            } _ 
         Equals New With { _ 
              .X = CDbl(e2.EntObj.X1), _ 
              .Y = CDbl(e2.EntObj.Y1) _ 
             } 

Dim LTest3 As IEnumerable = From e1 As QNCEntity In Shape.Entities _ 
           Join e2 As QNCEntity In Shape.Entities _ 
           On CDbl(e1.EntObj.X2) Equals CDbl(e2.EntObj.X1) _ 
           And CDbl(e1.EntObj.Y2) Equals CDbl(e2.EntObj.Y1) 

Благодаря

Answer 1

Экземпляр анонимного типа с нет ключевых свойств является Equal только к себе.

См: MSDN article on Anonymous Types, Header - Key Properties, Equality

Чтобы сделать первый запрос работать так же, как и второй, вы должны изменить свой первый образец кода, чтобы отметить X и Y свойства в качестве ключевых свойств:

Dim LTest2 As IEnumerable = From e1 As QNCEntity In Shape.Entities _ 
         Join e2 As QNCEntity In Shape.Entities _ 
         On New With { _ 
             Key .X = CDbl(e1.EntObj.X2), _ 
             Key .Y = CDbl(e1.EntObj.Y2) _ 
            } _ 
         Equals New With { _ 
              Key .X = CDbl(e2.EntObj.X1), _ 
              Key .Y = CDbl(e2.EntObj.Y1) _ 
             } 

ключевые поля будут сравниваться по значению для теста равенства вместо сравнения ссылок на два анонимных типа.

Answer 2

ли Width класс? Да? В этом случае первый запрос будет сравнивать объекты по ссылке, а второй будет сравнивать фактические значения. (... и ссылки не будут - конечно. - никогда не совпадают, потому что вы всегда создавать новый экземпляр)