Экспорт видео с обработки 3

Question

Я использую обработку-3.2.2 для аудиовизуализации. У меня есть код для воспроизведения визуализатора, но я не знаю, как сохранить его как файл видео (.mp4).

Вот что я написал:

import ddf.minim.*; 
import ddf.minim.analysis.*; 

Minim minim; 
AudioPlayer player; 
AudioMetaData meta; 
BeatDetect beat; 
int r = 200; 
float rad = 70; 
void setup() 
{ 
    size(500, 500); 
    //size(600, 400); 
    minim = new Minim(this); 
    player = minim.loadFile("son_final.mp3"); 
    meta = player.getMetaData(); 
    beat = new BeatDetect(); 
    player.play(); 
    //player.play(); 
    background(-1); 
    noCursor(); 
} 

void draw() 
{ 
    float t = map(mouseX, 0, width, 0, 1); 
    beat.detect(player.mix); 
    fill(#1A1F18,50); 
    noStroke(); 
    rect(0, 0, width, height); 
    translate(width/2, height/2); 
    noFill(); 
    fill(-2, 10); 
    if (beat.isOnset()) rad = rad*0.9; 
    else rad = 70; 
    ellipse(0, 0, 2*rad, 2*rad); 
    stroke(-1, 50); 
    int bsize = player.bufferSize(); 
    for (int i = 0; i < bsize - 1; i+=5) 
    { 
    float x = (r)*cos(i*2*PI/bsize); 
    float y = (r)*sin(i*2*PI/bsize); 
    float x2 = (r + player.left.get(i)*100)*cos(i*2*PI/bsize); 
    float y2 = (r + player.left.get(i)*100)*sin(i*2*PI/bsize); 
    line(x, y, x2, y2); 
    } 
    beginShape(); 
    noFill(); 
    stroke(-1, 50); 
    for (int i = 0; i < bsize; i+=30) 
    { 
    float x2 = (r + player.left.get(i)*100)*cos(i*2*PI/bsize); 
    float y2 = (r + player.left.get(i)*100)*sin(i*2*PI/bsize); 
    vertex(x2, y2); 
    pushStyle(); 
    stroke(-5); 
    strokeWeight(2); 
    point(x2, y2); 
    popStyle(); 
    } 
    endShape(); 
    if (flag) showMeta(); 
} 


void showMeta() { 
    int time = meta.length(); 
    textSize(50); 
    textAlign(CENTER); 
    text((int)(time/1000-millis()/1000)/60 + ":"+ (time/1000-millis()/1000)%60, -7, 21); 
} 

boolean flag =false; 
void mousePressed() { 
    if (dist(mouseX, mouseY, width/2, height/2)<150) flag =!flag; 
} 

void keyPressed() { 
    if(key=='e')exit(); 
} 

Я знаю, что могу импортировать библиотеку Moviemaker, но я не знаю, как использовать его в этом коде. Предложите некоторые изменения.

спасибо.

Answer 1

Для этого вы можете использовать библиотеку экспорта видео. Более подробная информация здесь: http://funprogramming.org/VideoExport-for-Processing/

Тогда все, что вам нужно сделать, это создать экземпляр VideoExport, а затем вызвать videoExport.saveFrame() в конце вашей draw() функции.

import com.hamoid.*; 

VideoExport videoExport; 

void setup() { 
    size(600, 600); 

    videoExport = new VideoExport(this, "basic.mp4"); 
} 
void draw() { 
    background(#224488); 
    rect(frameCount * frameCount % width, 0, 40, height); 

    videoExport.saveFrame(); 
} 

В настоящий момент имеется множество ресурсов. Я рекомендую googling «Обработка видео экспорта» за тонну результатов. Затем попробуйте что-нибудь и опубликуйте MCVE (не весь ваш проект), показывая, где именно вы застряли.