Вызов подпрограммы для каждого символа в строке - MIPS

Question

Я новичок в сборке MIPS, я хочу написать процедуру, которая берет адрес памяти строки и адрес памяти другой подпрограммы обратного вызова. Эта процедура будет проходить через каждую букву в строке и для каждой буквы вызовет подпрограмму (это печатает значение ASCII каждой буквы). Псевдо-код будет выглядеть примерно так:

string_for_each(string, subroutine) { 
    for_each_character_in_string { 
    subroutine(address_of(character)) 
    } 
} 

Это то, что мои рутинные выглядит как прямо сейчас:

string_for_each: 

    addi $sp, $sp, -4   # PUSH return address to caller 
    sw $ra, 0($sp) 

    jal loop 

    lw $ra, 0($sp)     # Pop return address to caller 
    addi $sp, $sp, 4 

    jr $ra 

loop: 

    lb $t1, 0($a0)     # Get current character 
    beq $t1, $zero, end_for_each # Done when reaching NULL character 
    jr $a1       # Call callback subroutine 
    addi $a0, $a0, 1    # Increment to get next character in string 
    j loop 

end_for_each: 

    jr $ra       # Return to caller 

Дело в том, что регистр $ a0 содержит адрес в строку, и $ a1 содержит адрес подпрограммы обратного вызова, а адрес текущего символа в строке, которая будет передана подпрограмме обратного вызова, также должна быть в $ a0. Как $ a0 может содержать как начальный адрес строки, так и текущий символ одновременно?

Подпрограмма обратного вызова:

ascii: 
    .data 
STR_the_ascii_value_is: 
    .asciiz "\nAscii('X') = " 

    .text 

    la $t0, STR_the_ascii_value_is 

    # Replace X with the input character 

    add $t1, $t0, 8 # Position of X 
    lb $t2, 0($a0) # Get the Ascii value 
    sb $t2, 0($t1) 

    # Print "The Ascii value of..." 

    add $a0, $t0, $zero 
    li $v0, 4 
    syscall 

    # Append the Ascii value 

    add $a0, $t2, $zero 
    li $v0, 1 
    syscall 


    jr $ra 

Answer 1

Вам нужно будет сохранить $a0 и $a1 в другом месте (обычно укладывают) на время вызова подпрограммы. Кроме того, ваш loop не является подпрограммой, нет причин для вызова, используя jal. С другой стороны, обратный вызов - это подпрограмма, вы должны позвонить ему, используя jalr. Что-то вдоль этих линий должно работать:

string_for_each: 

    addiu $sp, $sp, -12    # Need 3 locals for $a0, $a1 and $ra 
    sw $ra, 0($sp)     # Store $ra 
    sw $a1, 8($sp)     # Store $a1 

loop: 
    sw $a0, 4($sp)     # Store $a0 as it will be used for argument 
    lb $t0, 0($a0)     # Get current character 
    beq $t0, $zero, end_for_each # Done when reaching NULL character 
    jalr $a1      # Call callback subroutine 
    lw $a0, 4($sp)     # Reload $a0 
    lw $a1, 8($sp)     # $a1 could have changed (calling convention) 
    addi $a0, $a0, 1    # Increment to get next character in string 
    j loop 

end_for_each: 
    lw $ra, 0($sp)     # Reload return address to caller 
    addiu $sp, $sp, 12    # Free locals 
    jr $ra