Проверьте процесс, затем переключитесь на него?

Question

У меня есть код ниже, чтобы проверить, работает ли «chrome», когда я нажимаю кнопку Button1. Если он не запускает хром. Это работает, но я не знаю код, необходимый в инструкции If, чтобы переключиться на chrome, если он уже запущен. Надеюсь, это что-то очень простое.

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click 

    If Process.GetProcessesByName("chrome").Count > 0 Then 

     ??**SHOW RUNNING APPLICATION**?? 

    Else 
     Process.Start("C:\Program Files\Google\Chrome\Application\chrome.exe") 
    End If 


End Sub 

Answer 1

Как я уже упоминал выше, комментарий Chrome starts many instances of itself. Each tab has its own process, so how are you going to tell it which one to switch to?. Это зависит от того, какая вкладка была выбрана, когда вы сворачиваете окно или сворачиваете себя на панель задач. Ниже следует помочь вам, и это проверено и проверено. Единственная проблема заключается в том, что если вы открываете Chrome и имеете несколько вкладок, это нормально, но если вы создаете другой экземпляр Chrome, он не покажет второй экземпляр, он только выведет первый экземпляр ... Если вы закроете первый экземпляр, второй экземпляр, конечно, выйдет вперед.

Public Class Form1 

#Region "DLL Imports" 
    <System.Runtime.InteropServices.DllImport("User32.dll")> _ 
    Private Shared Function SetForegroundWindow(handle As IntPtr) As Boolean 
    End Function 

    <System.Runtime.InteropServices.DllImport("User32.dll")> _ 
    Private Shared Function ShowWindow(handle As IntPtr, nCmdShow As Integer) As Boolean 
    End Function 

    <System.Runtime.InteropServices.DllImport("User32.dll")> _ 
    Private Shared Function IsIconic(handle As IntPtr) As Boolean 
    End Function 
#End Region 

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click 
     StartOrShowProcess("chrome") 
    End Sub 


    Private Sub StartOrShowProcess(ByVal strProcessName As String) 
     Try 
      Dim handle As IntPtr 
      Dim proc As Process() = Process.GetProcessesByName(strProcessName) 
      If proc.Count > 0 Then 
       For Each procP As Process In proc 
        handle = procP.MainWindowHandle 
        If handle <> 0 AndAlso IsIconic(handle) Then 'Do we have a handle and is it minimized? 
         ShowWindow(handle, 9) 
         SetForegroundWindow(handle) 
        End If 
       Next 
      Else 'Not running or started... 
       Process.Start(strProcessName) 
      End If 

     Catch ex As Exception 
      'Handle your error... 
     End Try 
    End Sub 


End Class