Excel 2007 VBA Диапазон Переменные Ссылки Ячейки вне назначенного диапазона

Question

Я искал везде, но не смог выяснить, почему переменная диапазона может ссылаться на ячейки за пределами заданного диапазона.

Например, если я пишу код ниже:

Dim Rate as Range 
Set Rate = Range("A1:A5") 

For Each Cell In Rate 
     Debug.Print Cell.Value 
Next Cell 

Range("H6").Value = Rate(6).Value 
Range("H7").Value = Rate(7).Value 

выше процедура будет печатать только из 5 значений в «А1: А5» - НО последние 2 заявления вызывают значения в «A6 »и« A7 »для сохранения в« H6 »и« H7 ».

Поскольку переменная «Rate» присвоена только «A1: A5», почему она может ссылаться на другие ячейки в столбце A (то есть «A6» & «A7»)?

Я что-то не так? Любое понимание было бы высоко оценено!

Answer 1

Ничего страшного, это просто, как это работает. Мне лично нравится эта «функция».
Если вы скорее получите сообщение об ошибке, то вы можете использовать что-то вроде

Range("H6").Value = Rate.Value2(6, 1) ' .Value2 because .Value(6, 1) 

потому что Rate.Value2 даст вариантный массив 5 на 1. Или использовать .Value массив вместо Range:

Dim Rate ' as Variant 
Rate = Range("A1:A5").Value ' Variant/Variant(1 To 5, 1 To 1) 

Debug.Print Rate(5, 1) ' ok 
Debug.Print Rate(6, 1) ' Run-time error '9': Subscript out of range 

или

Dim Rate as Variant 
Rate = Application.Transpose(Range("A1:A5")) ' Variant/Variant(1 To 5) 

Debug.Print Rate(5) ' ok 
Debug.Print Rate(6) ' Run-time error '9': Subscript out of range 

В вашем случае Rate(6) коротка для Rate.Cells(6, 1), который похож на .Offset. Например:

Debug.Print Range("C3:D4")(1, 1).Address ' prints "$C$3" 
Debug.Print Range("C3:D4")(-1, -1).Address ' prints "$A$1" 

Единственный способ, которым я могу думать о получении ошибки с Range является использование вместо Areas:

Dim Rate As Areas 
Set Rate = Range("a1,a2,a3,a4,a5").Areas 

Debug.Print Rate(5) ' ok 
Debug.Print Rate(6) ' Run-time error '9': Subscript out of range