Неверное число аргументов или присвоение недействительного собственности в VBA

Question

Я получаю сообщение об ошибке

Неверное число аргументов или присвоение недействительного имущества

на этой линии:

Set hello = Range("O" & row, "Q" & row, "W" & row) 

Однако макрос работает плавно с Set hello = Range("O" & row). Таким образом, это означает, что этот макрос в порядке с выбором одной ячейки, но получение ошибки при выборе нескольких ячеек. Я не могу понять, какая настройка в моем макросе вызывает эту ошибку. Ценю вашу помощь.

Sub ImportDatafromotherworksheet() 
Dim wkbCrntWorkBook As Workbook 
Dim wkbSourceBook As Workbook 
Dim rngSourceRange As Range 
Dim rngDestination As Range 
Dim row As Integer 
Dim hello As Range 
Set wkbCrntWorkBook = ActiveWorkbook 
With Application.FileDialog(msoFileDialogOpen) 
    .Filters.Clear 
    .Filters.Add "Excel 2007-13", "*.xlsx; *.xlsm; *.xlsa" 
    .AllowMultiSelect = False 
    .Show 
    If .SelectedItems.Count > 0 Then 
     Workbooks.Open .SelectedItems(1) 
     Set wkbSourceBook = ActiveWorkbook 
     Set rngSourceRange = Application.InputBox(Prompt:="Select source row", Title:="Source Range", Default:="press Ctrl for multiple selection", Type:=8) 
     row = rngSourceRange.row 
     Set hello = Range("O" & row, "Q" & row, "W" & row) 

     wkbCrntWorkBook.Activate 
     Set rngDestination = Application.InputBox(Prompt:="Select destination cell", Title:="Select Destination", Default:="A1", Type:=8) 
     hello.Copy rngDestination 
     rngDestination.CurrentRegion.EntireColumn.AutoFit 
     wkbSourceBook.Close False 
    End If 
End With 
End Sub 

Answer 1

Что вы пытаетесь закончить с должно быть (например) Range("O5,Q5,W5")

Set hello = Range("O" & row & ",Q" & row & ",W" & row) 

все это одна строка, а не три.

Answer 2

Использование .Union также работает.

Set hello = Application.Union(Range("O" & row), Range("Q" & row), Range("W" & row)) 

Не знаю, лучше ли это, чем любое другое решение.