Последовательные номера счетов SQL-сервер

Question

У меня есть таблица счетов, которая имеет основной ключ InvoiceID (int identity). и столбцом InvoiceNumber, который является межсетевым. У меня есть другая таблица, которую я использую для создания номера счета-фактуры Invoice_Numbers (см. Ниже). Чтобы убедиться, что номер счета является уникальным и предотвратил пробелы, я выполнил приведенный ниже код. Может ли кто-нибудь просмотреть этот код и прокомментировать его надежность. Запуск SQL 2008 в многопользовательской среде.

Каковы шансы получения пользователями одинакового номера счета, когда они звонят тогда, при прокладке счетов?

 
IF EXISTS 
    (SELECT * 
    FROM sys.objects 
    WHERE object_id = OBJECT_ID(N'[Imports].[Invoices_Numbers]') 
      AND type IN (N'U')) 
    DROP TABLE [Imports].[Invoices_Numbers]
 

GO
 

CREATE TABLE [Imports].[Invoices_Numbers] 
    (
    [InvoiceNumber] [INT] IDENTITY(1, 1) NOT NULL 
    ,[Deleted]  [BIT] NOT NULL 
    ,[Used]   [BIT] NOT NULL, 
    CONSTRAINT [PK_Invoices_Numbers] PRIMARY KEY CLUSTERED ([InvoiceNumber] ASC)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON) ON [PRIMARY] 
) 
ON [PRIMARY]
 

GO
 

ALTER PROCEDURE [Imports].[Get_Invoice_Number] 
(
    @InvoiceNumber INT OUTPUT 
) 
AS 
    BEGIN 
     DECLARE @NewNumber INT 
     DECLARE @MinNumber INT
 

BEGIN TRAN 

    SELECT @MinNumber = MIN(InvoiceNumber) 
    FROM Imports.Invoices_Numbers 

    IF @MinNumber > 1 
    BEGIN 
     SET IDENTITY_INSERT Imports.Invoices_Numbers ON; 

     INSERT Imports.Invoices_Numbers 
     (
      Invoicenumber 
      ,Deleted 
      ,Used 
     ) 
     VALUES 
     (
      1 
      ,0 
      ,1 
     ) 
     SET IDENTITY_INSERT Imports.Invoices_Numbers OFF; 
     SET @NewNumber=1 
    END 
    ELSE 
    BEGIN 
     WITH Gaps 
      AS (SELECT TOP 1 a.InvoiceNumber + 1 AS GapValue 
       FROM Imports.Invoices_Numbers a 
       WHERE NOT EXISTS 
          (SELECT * 
          FROM Imports.Invoices_Numbers b 
          WHERE b.InvoiceNumber = a.InvoiceNumber + 1) 
         AND a.InvoiceNumber < 
          (SELECT MAX(InvoiceNumber) 
          FROM Imports.Invoices_Numbers)) 
     SELECT @NewNumber = GapValue 
     FROM Gaps 

     IF @NewNumber IS NULL 
      BEGIN 
       SELECT TOP 1 @NewNumber = InvoiceNumber 
       FROM Imports.Invoices_Numbers 
       WHERE Used = 0 
        AND Deleted = 0 
       ORDER BY InvoiceNumber 

       IF @NewNumber IS NULL 
       BEGIN 
        INSERT Imports.Invoices_Numbers 
        (
         Deleted 
         ,Used 
        ) 
        VALUES 
        (
         0 
         ,1 
        ) 
        SELECT @NewNumber = SCOPE_IDENTITY() 
       END 
       ELSE 
       BEGIN 
        UPDATE Imports.Invoices_Numbers 
        SET Used = 1 
        WHERE InvoiceNumber = @NewNumber 
       END 
      END 
     ELSE 
      BEGIN 
       SET IDENTITY_INSERT Imports.Invoices_Numbers ON; 

       INSERT Imports.Invoices_Numbers 
       (
       Invoicenumber 
       ,Deleted 
       ,Used 
      ) 
       VALUES 
       (
       @NewNumber 
       ,0 
       ,1 
      ) 
       SET IDENTITY_INSERT Imports.Invoices_Numbers OFF; 
      END 
    END 

    SELECT @InvoiceNumber = @NewNumber 

    COMMIT TRAN 

END

Answer 1

Ваше решение выглядит немного сложным. Я бы не пересчитал, используя set identity_insert для чего угодно, кроме задач импорта данных.

Для обеспечения уникальности, я бы первым добавить уникальное ограничение:

alter table Invoices add constraint UX_Invoices_InvoiceNr unique 

Затем вы можете использовать SQL заявление, как это вставить счет:

while 1=1 
    begin   
    declare @new_nr int 
    select @new_nr = max(InvoiceNr) + 1 
    from dbo.Invoices 

    if @new_nr is null 
     set @new_nr = 1 

    insert dbo.Invoices 
      (InvoiceNr, ...) 
    values (@new_nr, ...) 

    if @@rowcount = 1 
     break 
    end