VBA: Else without If Error

Question

Я пытаюсь запустить следующий код, но я продолжаю получать Else без If Error в первом sub. Код должен проходить через столбец, открывать веб-страницы, если в ячейке есть URL-адрес, а затем сохранить информацию о странице в виде текстового файла. Если URL-адрес отсутствует, он просто сохраняет текст в этом файле в виде текстового файла. Я не могу понять, как изменить синтаксис, чтобы заставить его работать.

Sub LoopOverB() 

Dim myRow As Long 

myRow = 10 

While Worksheets("Input_Format_A").Cells(myRow, 2).value <> "" 
    If InStr(1, Worksheets("Input_Format_A").Cells(myRow, 2).value, "http://", vbTextCompare) Then Call url_Test(Worksheets("Input_Format_A").Cells(myRow, 2).value, "C:\mallet\test\" & Worksheets("Input_Format_A").Cells(myRow, 1).value & ".txt") 
     myRow = myRow + 1 
    Else 
     Open "C:\mallet\test\" & Worksheets("Input_Format_A").Cells(myRow, 1) & ".txt" For Append As #1 
     Print #1, Worksheets("Input_Format_A").Cells(myRow, 2).value 
     Close #1 

     myRow = myRow + 1 
    End If 
Wend 
End Sub 


Sub url_Test(URL As String, Filename As String) 

Dim FSO As Object 
Dim ieApp As Object 
Dim Txt As String 
Dim TxtFile As Object 

Set FSO = CreateObject("Scripting.FileSystemObject") 
Set TxtFile = FSO.OpenTextFile(Filename, 2, True, -1) 

Set ieApp = CreateObject("InternetExplorer.Application") 
ieApp.Visible = True 
ieApp.Navigate URL 

While ieApp.Busy Or ieApp.ReadyState <> 4 
    DoEvents 
Wend 

Txt = ieApp.Document.body.innerText 
TxtFile.Write Txt 
TxtFile.Close 

ieApp.Quit 

Set ieApp = Nothing 
Set FSO = Nothing 
End Sub 

Answer 1

На линии с первым If, вы должны перейти на новую строку после Then, в противном случае ваш If будет неявным закрыт.

'Good (in this case) 
If <condition> Then  
    DoSomething 
    myRow = myRow + 1 
Else 
    DoSomething Different 
End if 


'NOT good 
If <condition> Then DoSomething 
    'the if is now "closed" !!! 
    myRow = myRow + 1 
Else 
    DoSomething Different 
End if