Получение подстроки из списка строк

Question

Итак, в рамках изучения языка я хотел проверить три строки для определенного шаблона и вернуть только первое совпадение этого шаблона.

Моя попытка была использовать комбинацию находке и регулярных выражений для просмотра списка:

def date = [ 
    "some string", 
    "some other string 11.11.2000", 
    "another one 20.10.1990" 
].find { title -> 
    title =~ /\d{2}\.\d{2}\.\d{4}/ 
} 

Этот вид работ, оставляя всю строку в date.

Моя цель, однако, состоит в том, чтобы в итоге получилось «11.11.2000» в date; Я предполагаю, что каким-то образом я должен иметь доступ к группе захвата, но как?

Answer 1

Если вы хотите вернуть определенное значение при поиске соответствующего элемента в коллекции (который, как и ваш случай, может быть частью этого элемента), вам необходимо использовать findResult.

Ваш код может выглядеть следующим образом

def date = [ 
    "some string", 
    "some other string 11.11.2000", 
    "another one 20.10.1990" 
].findResult { title -> 
    def res = title =~ /\d{2}\.\d{2}\.\d{4}/ 
    if (res) { 
     return res[0] 
    } 
} 

Answer 2

Расширение ответ UnholySheep, вы можете также сделать это:

assert [ 
    "some string", 
    "some other string 11.11.2000", 
    "another one 20.10.1990" 
].findResult { title -> 
    def matcher = title =~ /\d{2}\.\d{2}\.\d{4}/ 
    matcher.find() ? matcher.group() : null 
} == '11.11.2000' 

Для всех матчей, просто использовать findResults вместо findResult, как это:

assert [ 
    "some string", 
    "some other string 11.11.2000", 
    "another one 20.10.1990" 
].findResults { title -> 
    def matcher = title =~ /\d{2}\.\d{2}\.\d{4}/ 
    matcher.find() ? matcher.group() : null 
} == ['11.11.2000', '20.10.1990']