Деревья выражений в Linq To Entities

Question

Я пытаюсь сделать метод расширения, который принимает выражение, указывающее на свойство на сущности, и константную строку для сравнения с использованием String.Contains, которая сначала проверяет, является ли строка null или empty, и применяет фильтр только в том случае, если строка имеет значение. Это моя первая проблема в Expression Trees, хотя, поэтому я не совсем уверен, что происходит, и теперь у меня есть исключение, которое я не уверен, как вылечить ...

Я до сих пор :

<System.Runtime.CompilerServices.Extension()> 
    Public Function CheckAndFilter(Of T)(source As System.Linq.IQueryable(Of T), expressionField As System.Linq.Expressions.Expression(Of System.Func(Of T, String)), compareTo As String) As IQueryable(Of T) 


     If String.IsNullOrEmpty(compareTo) Then 
      Return source 
     Else 
      Dim memberExp As Expressions.MemberExpression = DirectCast(expressionField.Body, Expressions.MemberExpression) 

      Dim param = Expressions.Expression.Parameter(GetType(T)) 
      Dim method As Reflection.MethodInfo = GetType(String).GetMethod("Contains") 

      Dim compareToExpression = Expressions.Expression.Constant(compareTo) 
      Dim finalExpr = Expressions.Expression.Call(memberExp, method, compareToExpression) 

      Dim lambda = Expressions.Expression.Lambda(Of Func(Of T, Boolean))(finalExpr, param) 
      Return source.Where(lambda) 
     End If 
    End Function 

Я звоню это так, против DbContext, где у меня есть Customer объект со свойством FirstName строки:

Dim results = repository.Customers.CheckAndFilter(Function(c) c.FirstName, searchText) 

И за исключением является:

{"The parameter 'c' was not bound in the specified LINQ to Entities query expression."} 

Любые мысли?

Answer 1

A ha!

Это потому, что я объявил новый параметр, а не повторно использовать один принятый в с помощью выражения ...

<System.Runtime.CompilerServices.Extension()> 
Public Function CheckAndFilter(Of T)(source As System.Linq.IQueryable(Of T), expressionField As System.Linq.Expressions.Expression(Of System.Func(Of T, String)), compareTo As String) As IQueryable(Of T) 


    If String.IsNullOrEmpty(compareTo) Then 
     Return source 
    Else 
     Dim memberExp As Expressions.MemberExpression = DirectCast(expressionField.Body, Expressions.MemberExpression) 

     Dim method As Reflection.MethodInfo = GetType(String).GetMethod("Contains") 

     Dim compareToExpression = Expressions.Expression.Constant(compareTo) 
     Dim finalExpr = Expressions.Expression.Call(memberExp, method, compareToExpression) 

     Dim lambda = Expressions.Expression.Lambda(Of Func(Of T, Boolean))(finalExpr, expressionField.Parameters) 
     Return source.Where(lambda) 
    End If 
End Function