Как удалить последний символ файла

Question

Я использую это командные файлы, чтобы создать список файлов

@echo off 
(for /f "delims=" %%a in ('dir/b/a-d *.tex') do echo %%a,)>liste.dat 

В результате, как это

file1.tex, 
file2.tex, 
file3.tex, 
... 
lastfile.tex, 

Как удалить последнюю запятую?

Answer 1

@echo off 
setlocal EnableDelayedExpansion 

set "comma=" 
< NUL (
for %%a in (*.tex) do (
    set /P "=!comma!%%a" 
    set comma=,^ 
%Empty line% 
) 
echo/ 
) > liste.dat 

EDIT: Ответить на комментарий

Ops! Когда я разрабатывал этот код, который я только отображается вывод на экране, где он выглядит правильно:

C:\> test.bat 
One.tex, 
Three.tex, 
Two.tex 

Даже если вывод направляется в файл, а файл отображается на экране, вывод выглядит правильно:

C:\> test.bat > output.txt 

C:\> type output.txt 
One.tex, 
Three.tex, 
Two.tex 

Однако характер вставляется после каждой запятой просто LF, так что если этот файл открыт с помощью блокнота, ЛФ являются не преобразованы в «конец строки»; просто cmd.exe экран выход преобразует LF в CR + LF пару («приготовленный выход» вместо «сырой выход»).

Способ исправить эту деталь вставляет полный CR + LF пары после каждой запятой:

@echo off 
setlocal EnableDelayedExpansion 

for /F %%a in ('copy /Z "%~F0" NUL') do set "CR=%%a" 

set "comma=" 
< NUL (
for %%a in (*.tex) do (
    set /P "=!comma!%%a" 
    set comma=,!CR!^ 
%Empty line% 
) 
echo/ 
) > liste.dat 

Answer 2

Проблема в том, что вы не знаете, сколько строк или файлов будет. Таким образом, вам придется использовать две петли, как ваш код написан. Один для подсчета строк и один для выполнения операций. Легче иметь другую обработку для первой строки, а не для последней. Так как об этом:

@echo off 
SETLOCAL EnableDelayedExpansion 
SET /a i=0 
(for /f "delims=" %%a in ('dir /b/a-d *.tex') do (
    IF !i!==1 (
     echo ,%%a 
    ) ELSE (
     ECHO %%a 
     SET /a i=1 
    ) 
) 
)>liste.txt 

Это создаст что-то вроде этого:

file1.tex 
,file2.tex 
,file3.tex 
... 
,lastfile.tex 

Это кажется эквивалентной до нужного выхода. Если вы действительно хотите иметь , в конце строк, а не в начале следующего, скажите мне, и я обновлю код, но он будет довольно уродливым.

Answer 3

@echo off 
SETLOCAL EnableDelayedExpansion 
SET "in=" 
(
for %%a in (*.tex) do (
    IF "!in!"=="" (
     set in=%%a 
    ) ELSE (
     echo !in!, 
     set in=%%a 
    ) 
) 
echo !in! 
)>liste.dat