Как показать ответ потока байтов

Question

Мой REST API возвращает PDF-документ в байтах, и мне нужно вызвать этот API и показать документ PDF на странице ASP для предварительного просмотра пользователю.

Я попытался

Response.Write HttpReq.responseBody 

но пишет некоторые нечитаемый текст на странице. httpReq - это мой объект, через который я вызываю REST API.

Ответ REST API:

Request.CreateResponse(HttpStatusCode.OK, pdfStream, MediaTypeHeaderValue.Parse("application/pdf")) 

Answer 1

В классическом ASP, Response.Write() используется для передачи текстовых данных обратно в браузер, используя CodePage и Charset свойства, определенные на Response объекта (по умолчанию это унаследованный от текущий сеанс и расширение конфигурации сервера IIS).

Чтобы отправить двоичные данные обратно в браузер, используйте Response.BinaryWrite().

Вот краткий пример (фрагмент, основанный на том, что у вас уже есть двоичный код от httpReq.ResponseBody);

<% 
Response.ContentType = "application/pdf" 
'Make sure nothing in the Response buffer. 
Call Response.Clear() 
'Force the browser to display instead of bringing up the download dialog. 
Call Response.AddHeader("Content-Disposition", "inline;filename=somepdf.pdf") 
'Write binary from the xhr responses body. 
Call Response.BinaryWrite(httpReq.ResponseBody) 
%> 

В идеале, при использовании REST API с помощью XHR (или любой URL по этому вопросу) вы должны быть проверяя httpReq.Status, чтобы обрабатывать ошибки отдельно возвращения в двоичном, даже установить другой content-type, если есть ошибка.

Вы можете перестроить приведенный выше пример;

<% 
'Make sure nothing in the Response buffer. 
Call Response.Clear() 
'Check we have a valid status returned from the XHR. 
If httpReq.Status = 200 Then 
    Response.ContentType = "application/pdf" 
    'Force the browser to display instead of bringing up the download dialog. 
    Call Response.AddHeader("Content-Disposition", "inline;filename=somepdf.pdf") 
    'Write binary from the xhr responses body. 
    Call Response.BinaryWrite(httpReq.ResponseBody) 
Else 
    'Set Content-Type to HTML and return a relevant error message. 
    Response.ContentType = "text/html" 
    '... 
End If 
%> 

---

• Content-Disposition:What are the differences between “inline” and “attachment”?

• A: ASP Classic, Download big files does not work on certain servers(полезные советы по отрывов загрузками)

Answer 2

Вы должны определить тип содержимого ответа как PDF:

Response.ContentType = "application/pdf" 

Затем записать двоичные данные в ответ:

Response.BinaryWrite(httpReq.ResponseBody) 

Полный пример:

url = "http://yourURL" 

Set httpReq = Server.CreateObject("MSXML2.ServerXMLHTTP") 
httpReq.Open "GET", url, False 
httpReq.Send 

If httpReq.Status = "200" Then 
    Response.ContentType = "application/pdf" 
    Response.BinaryWrite(httpReq.ResponseBody) 
Else 
    ' Display an error message 
    Response.Write("Error") 
End If