VB-скрипт, не возвращающий значения

Question

Function NextMonthName(dateval) 
    Dim tmp : tmp = DateAdd("m", 1, dateval) 
    NextMonthName = MonthName(Month(tmp)) 
    return NextMonthName 
    Wscript.Echo NextMonthName 
    End Function 

Function PrevMonthName(dateval) 
    Dim tmp : tmp = DateAdd("m", -1, dateval) 
    NextMonthName = MonthName(Month(tmp)) 
    return NextMonthName 
    End Function 

Я запускаю вышеупомянутый скрипт VB, и он отлично работает без вывода. Я хочу результат в текстовом файле. Я также не могу получить вывод в консоли.

Answer 1

Поскольку не существует в VBScript нет return, это

Option Explicit 

Function NextMonthName(dateval) 
    Dim tmp : tmp = DateAdd("m", 1, dateval) 
    NextMonthName = MonthName(Month(tmp)) 
    return NextMonthName 
End Function 

WScript.Echo NextMonthName(Now) 

проваливается с

...\31436343.vbs(6, 5) Microsoft VBScript runtime error: Variable is undefined: 'return' 

(выглядит, как вы задали вопрос, основанный на коде, содержащий глобальный "On Error Resume Next")

Удаление обижая линии -

Option Explicit 

Function NextMonthName(dateval) 
    Dim tmp : tmp = DateAdd("m", 1, dateval) 
    NextMonthName = MonthName(Month(tmp)) 
End Function 

WScript.Echo NextMonthName(Now) 

решает эту проблему:

cscript 31436343.vbs 
August 

Answer 2

Для записи на выводе в текстовый файл;

Option Explicit 
Dim Title,dateval,Message 
Title = "The previous Month and The Next Month" 
dateval = Now() 
Message = "The previous Month : "& PrevMonthName(dateval) & " "& Year(dateval) & vbCrLf &_ 
"The Next Month :"& NextMonthName(dateval) & " "& Year(dateval) 
MsgBox Message,VbInformation,Title 
WriteLog Message 
'******************************************* 
Function PrevMonthName(dateval) 
    Dim tmp : tmp = DateAdd("m", -1, dateval) 
    PrevMonthName = MonthName(Month(tmp)) 
End Function 
'******************************************* 
Function NextMonthName(dateval) 
    Dim tmp : tmp = DateAdd("m", 1, dateval) 
    NextMonthName = MonthName(Month(tmp)) 
End Function 
'******************************************* 
Sub WriteLog(strText) 
    Dim fs,ts,LogFile 
    Const ForWriting = 2 
    LogFile = Left(Wscript.ScriptFullName, InstrRev(Wscript.ScriptFullName, ".")) & "log" 
    Set fs = CreateObject("Scripting.FileSystemObject") 
    Set ts = fs.OpenTextFile(LogFile,ForWriting,True) 
    ts.WriteLine strText 
    ts.Close 
End Sub 
'********************************************