Я знаю, что это старый вопрос, но это может помочь любому, у кого есть такая же проблема. Особенно, когда вам нужно отменить набор изменений, который был проверен давно на другой ветке.
Обновление WORKSPACE_ROOT и TFS_BRANCH_ROOT в следующем пакетном файле. Назовите его, например. RollbackMigrate.cmd и всегда запускайте его из корня рабочей области.
Этот пакетный файл будет: аргументы
- Разбор - только один аргумент является изменение номер набора
- Найдите имя текущего рабочего пространства, и это путь на TFS
- Найти путь источника TFS для миграции
- Карта источника в текущее рабочее пространство
- отката изменения набора
- Создать Полочка установить и отменить проверку из
- Снимите отображение временного
- Unshelve ранее созданную полки набора и перенести его
- вам просто нужно автоматически объединять shelveset в новом окне
- Удалить временный Shelve набор
- Checkin
- Вам необходимо изменить комментарий, ноты и ссылку на работу
@echo off
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
set WORKSPACE_ROOT=D:\PathToMyWorkspaces
set TFS_BRANCH_ROOT=$/Project/Branches
:01_ARGUMENT_PARSING
echo Rollback changes from another branch
if [%1]==[] (
set /P CHANGESET=Enter changeset number:
if [!CHANGESET!]==[] (
echo Changeset number is required! Exiting!
exit /B 1
)
) else (
set CHANGESET=%1
shift
)
set SHELVE_NAME="Auto shelved rollback of %CHANGESET%"
:02_FIND_MY_WORKSPACE_NAME
for %%i in (.) do (
set WORKSPACE=%%~nxi
)
if not [%CD%]==[%WORKSPACE_ROOT%\%WORKSPACE%] (
echo This script works only in the root of workspace e.g. D:\PathToMyWorkspaces\MyWorkspace
exit /B 1
)
echo Current workspace is %WORKSPACE%
for /f %%i in ('tf workspaces %WORKSPACE% /noprompt /format:detailed ^| grep -om 1 "$/[^:]\+"') do (
if not [%DST%]==[] (
echo Cannot work on workspaces with more mappings! Exiting!
exit /B 2
)
set DST=%%i
echo Found destination path for migration: "%%i"
)
:03_VIEW_CHANGESET
for /f %%i in ('tf changeset 1570888 ^| grep -om 1 "%TFS_BRANCH_ROOT%/[^/]\+/[^/]\+"') do (
set SRC=%%i
echo Found source path for migration: "%%i"
)
if [%SRC%]==[] (
echo Cannot find path to source branch! Exiting!
exit /B 3
)
for %%i in (%SRC%) do (
set SRC_BRANCH=%%~nxi
)
:04_MAP_SOURCE
set TMP_SRC_PATH=%WORKSPACE_ROOT%\%WORKSPACE%_%SRC_BRANCH%
echo Create temporary mapping for source branch in %TMP_SRC_PATH%
mkdir %TMP_SRC_PATH%
echo Creating mapping for "%SRC%" to "%TMP_SRC_PATH%"
tf workfold /map %SRC% %TMP_SRC_PATH%
if %errorlevel% NEQ 0 (
echo Can't create mapping for "%SRC%", exiting!
exit /B 4
)
:05_ROLLBACK_CHANGESET
echo Performing rollback of changeset %CHANGESET%
tf rollback /changeset:%CHANGESET% /lock:checkin /keepmergehistory
:06_SHELVE_ROLLBACK
echo Shelving rollback
tf shelve /comment:%SHELVE_NAME% %SHELVE_NAME% /noprompt /move /replace
:07_UNMAP_AND_DELETE_TEMPORARY
echo Unmapping "%SRC%" from "%TMP_SRC_PATH%"
tf workfold /unmap "%TMP_SRC_PATH%"
echo Deleting "%TMP_SRC_PATH%"
rmdir /S /Q "%TMP_SRC_PATH%"
:08_UNSHELVE_MIGRATE
echo Unshelving the rollback...
tfpt unshelve /migrate /source:"%SRC%" /target:"%DST%" %SHELVE_NAME% /noprompt
:09_DELETE_THE_SHELVESET
echo Deleting the shelveset
tf shelve /delete %SHELVE_NAME% /noprompt
:10_CHECKIN
echo Checking in the rollback...
tf checkin
Есть много слияния сделано так, что совершал (тот, который я должен откатить) и что лежит в ревизии грандиозной грандиозной грандиозной родительской ветви :( – IsmailS