W1035: Возвращаемое значение функции 'Take' может быть не определено

Question

У меня есть функция, чтобы постить элемент из словаря, если что-то пойдет не так, следует выбросить исключение. Код выглядит вполне нормально.

type 
    ENoSuchElementException = class(Exception); 
var 
    FResults: TDictionary<Cardinal, TObject> = TDictionary<Cardinal, TObject>.Create; 
    FLock: TCriticalSection = TCriticalSection.Create; 

/// <exceptions cref="ENoSuchElementException">Element does not exist</exceptions> 
function Take(Id: Cardinal): TObject; 
begin  
    FLock.Acquire; 
    try 
    try 
     Result := FResults[Id]; // here may throw exception 
     FResults.Remove(Id); 
    except 
     on E: Exception do 
     begin 
     raise ENoSuchElementException.Create(E.ToString); 
     end; 
    end; 
    finally 
    FLock.Release; 
    end; 
end; 

Но компилятор Delphi xe4 жалуется W1035: Return value of function 'Take' might be undefined.

Я внезапно так смущен. Если выбрано исключение, почему код все еще ожидает возвращаемое значение? Означает ли это, что try...finally будет есть исключение? Может ли кто-нибудь указать на проблему моего кода?

ПОСТАНОВИЛ: Как указывал Дэвид, try...except следует переместить на наружную сторону. Благодаря!

Answer 1

Это, по-видимому, ложный позитив, сообщенный 32-битным компилятором. 64-битный компилятор не сообщает о предупреждении для вашего кода. И 64-битный компилятор верен. Возможно, 32-битный компилятор видит, что вы ловите исключение и не обнаруживаете, что вы всегда впоследствии вызываете другое исключение.

Один из способов обойти неправильную диагностику 32-битного компилятора заключается в том, чтобы сделать try/except, кроме внешнего блока. Рассмотрим следующий SSCCE:

{$APPTYPE CONSOLE} 

uses 
    SysUtils; 

procedure Foo; 
begin 
end; 

function Take1(const Id: Integer): Integer; 
begin 
    try 
    try 
     Foo; 
     Result := 42; 
    except 
     on E:Exception do 
     begin 
     raise Exception.Create(E.ToString); 
     end; 
    end; 
    finally 
    end; 
end; 

function Take2(const Id: Integer): Integer; 
begin 
    try 
    try 
     Foo; 
     Result := 42; 
    finally 
    end; 
    except 
    on E:Exception do 
    begin 
     raise Exception.Create(E.ToString); 
    end; 
    end; 
end; 

begin 
end. 

выход компилятора является:

 
[dcc32 Warning] W1035 Return value of function 'Take1' might be undefined 

Итак, Take1 моя упрощенная версия кода. 32-битный компилятор предупреждает об этом. И Take2 своп заказа except и finally. И компилятор не предупреждает.

Возможно, это обходное решение не для вас, но вам придется придумать что-то подобное.

Суть в том, что ваш анализ правильный, а компилятор ошибочен.

Answer 2

Дэвид Heffernan дал вам самый прямой ответ, однако альтернативой является полностью избежать колодку try/except и использовать TryGetValue метод TDictionary. Пройдя немного дальше, вы можете, если вы хотите, чтобы также избавиться от отдельного объекта запирающего:

var FResults: TDictionary<Cardinal, TResult>; 

function Take(Id: Cardinal): TResult; 
begin  
    TMonitor.Enter(FResults); 
    try 
    if FResults.TryGetValue(Id, Result) then 
     FResults.Remove(Id) 
    else 
     Abort; 
    finally 
    TMonitor.Exit(FResults); 
    end; 
end; 

TMonitor исторически имела существенные ошибки, но это будет хорошо в xe4.