Подпрограммы модуля сортировки по алфавиту

Question

Я хотел бы отсортировать мои подпрограммы модуля в алфавитном порядке (у меня много подпрограмм, и я думаю, что будет легче редактировать файл, если подпрограммы упорядочены в файле). К примеру приведены A.pm:

package A; 
use warnings; 
use strict; 

sub subA { 
    print "A\n"; 
} 

sub subC { 
    print "C\n"; 
} 
sub subB { 
    print "B\n"; 
} 

1; 

Я хотел бы запустить sortSub A.pm дает:

package A; 
use warnings; 
use strict; 

sub subA { 
    print "A\n"; 
} 
sub subB { 
    print "B\n"; 
} 
sub subC { 
    print "C\n"; 
} 
1; 

Есть ли ресурс CPAN, который может помочь с этой задачей?

Answer 1

Для разбора и форматирования кода Perl, вы должны использовать PPI.

Это тот самый инструмент, который Perl::Critic и Perl::Tidy используют для совершения всех своих умений.

В этом случае я изучил код для PPI::Dumper, чтобы получить представление о том, как перемещаться по дереву документов, возвращаемому PPI.

Далее будет проанализирован исходный код и отдельные разделы, содержащие подпрограммы и комментарии. Он свяжет комментарии, pod и whitespace перед подпрограммой с ним, а затем он сортирует все соседние подмножества по их именам.

use strict; 
use warnings; 

use PPI; 
use Data::Dump; 

my $src = do { local $/; <DATA> }; 

# Load a document 
my $doc = PPI::Document->new(\$src); 

# Save Sub locations for later sorting 
my @group =(); 
my @subs =(); 

for my $i (0 .. $#{ $doc->{children} }) { 
    my $child = $doc->{children}[$i]; 

    my ($subtype, $subname) 
     = $child->isa('PPI::Statement::Sub') 
     ? grep { $_->isa('PPI::Token::Word') } @{ $child->{children} } 
     : ('', ''); 

    # Look for grouped subs, whitespace and comments. Sort each group separately. 
    my $is_related = ($subtype eq 'sub') || grep { $child->isa("PPI::Token::$_") } qw(Whitespace Comment Pod); 

    # State change or end of stream 
    if (my $range = $is_related .. (!$is_related || ($i == $#{ $doc->{children} }))) { 
     if ($is_related) { 
      push @group, $child; 

      if ($subtype) { 
       push @subs, { name => "$subname", children => [@group] }; 
       @group =(); 
      } 
     } 

     if ($range =~ /E/) { 
      @group =(); 

      if (@subs) { 
       # Sort and Flatten 
       my @sorted = map { @{ $_->{children} } } sort { $a->{name} cmp $b->{name} } @subs; 

       # Assign back to document, and then reset group 
       my $min_index = $i - $range + 1; 
       @{ $doc->{children} }[ $min_index .. $min_index + $#sorted ] = @sorted; 

       @subs =(); 
      } 
     } 
    } 
} 

print $doc->serialize; 

1; 

__DATA__ 
package A; 
use warnings; 
use strict; 

=comment 
Pod describing subC 
=cut 
sub subC { 
    print "C\n"; 
} 

INIT { 
    print "Hello World"; 
} 

sub subB { 
    print "B\n"; 
} 

# Hello subA comment 
sub subA { 
    print "A\n"; 
} 

1; 

Выход:

package A; 
use warnings; 
use strict; 

=comment 
Pod describing subC 
=cut 
sub subC { 
    print "C\n"; 
} 

INIT { 
    print "Hello World"; 
} 

# Hello subA comment 
sub subA { 
    print "A\n"; 
} 

sub subB { 
    print "B\n"; 
} 

1; 

Answer 2

Во-первых, вот мое решение;

#!/bin/sh 
TOKEN=sub 

gsed -e ':a;N;$!ba;s/\n/__newline__/g' "$1" > "$1.out" 
gsed -i "s/__newline__\\s*$TOKEN\W/\\nsub /g" "$1.out" 
sort $1.out -o $1.out 
gsed -i 's/__newline__/\n/g' $1.out 

Использование: token_sort.sh myfile.pl

Вот как это работает;

• Заменить все символы новой строки с заполнителем, __newline__
• вырваться из всех $TOKENS, в этом случае подводные лодки, к их собственной линии
• Сортировка линий с помощью UNIX сортировать
• Заменить обратно все переводы строк
• Теперь у вас должна быть отсортированная копия вашего файла в myfile.pl.out

Несколько оговорок;

• Добавить комментарий «# Something» или «#!/Usr/bin/env perl» в начало файла; это обеспечит сортировку блока заголовка вверху.
• Отсортированный блок будет началом текущего суб-комментария к следующим суб-комментариям выше, суб будет сортироваться с предыдущим под.
• Вы должны использовать гну-СЭД для этой работы, на макинтош это означает делать «варево установить гну-СЭД»