пролога - генерировать список со случайными значениями

Question

Я пытаюсь создать список со случайными значениями от 1 до 10, но когда я запускаю код, я получаю «ложь» ...

geraL(0,_). 
geraL(C,Y):- 
    C is C-1, 
    random(1,10,U), 
    Y = [U|Y], 
    geraL(C,Y). 


?-geraL(13,X). 

Answer 1

Мы будет покрывать каждую проблему в отдельности:

• geraL(0, _) говорит, что если вы хотите ноль случайных чисел, все, что может быть результатом. Я уверен, это не то, что вы имеете в виду. Каким должен быть результат, если число элементов равно 0?

• Вы должны иметь ограничение, которое говорит C > 0 в вашем общем случае, чтобы избежать выполнения этого правила, когда это не требуется

• C is C - 1 всегда будет терпеть неудачу, потому что при любом значении C, C и C-1 никогда не могут быть одинаковыми стоимость. Вы не можете переустановить переменную, если она имеет значение в предложении предиката, кроме как с помощью обратного отслеживания.

• Хотя допустимо Y = [U|Y], это циклическое определение списка (список, определенный в терминах самого себя с дополнительным элементом главы), и я уверен, что это не то, что вы хотите.

Если вы исправите эти пункты, ваша программа будет работать. Первые два фиксируются с использованием вспомогательной (другой) переменной. Последний из них правильно определяет базовый случай, чтобы связать пустой список с 0, а не анонимной переменной.

geraL(0, []). % Fix for item 1: zero values should be an empty list 
geraL(C, Y):- 
    C > 0,  % Fix for item 2 
    C1 is C-1, % Fix for item 3: use C1 for the new value 
    random(1, 10, U), 
    Y = [U|T], % Fix for item 4: use T for the new value (tail) 
    geraL(C1, T). 

Answer 2

Существует встроенный предикат findnsols/4 который находит самое большее N решений.

Этот предикат может использоваться для эквивалента цикла. Поскольку random/3 является детерминированным, нам нужно добавить repeat/0 в цель, чтобы повторить его.

geraL(C, Y) :- findnsols(C, U, (repeat, random(1, 10, U)), Y). 

---

Кроме того, обратите внимание, что random/3 устарел в SWI Prolog; рекомендуется вместо этого использовать random/1 или random_between/3.
В частности, random/3 исключает верхнюю границу, поэтому random(1, 10, U) никогда не даст U = 10.

Answer 3

Не нужно писать рекурсивный код!

random/3 Просто используйте, length/2 и maplist/2 так:

 
?- length (Zs, 13), maplist (random (0,10), Zs). 
Zs = [8, 9, 3, 5, 0, 7, 6, 7, 9, 9, 2, 4, 7]. 

?- length(Zs, 13), maplist(random(0,10), Zs). 
Zs = [1, 7, 7, 6, 2, 5, 2, 9, 9, 2, 0, 7, 1]. 

?- length(Zs, 13), maplist(random(0,10), Zs). 
Zs = [4, 6, 7, 0, 1, 3, 4, 9, 0, 8, 3, 8, 5]. 

?- length(Zs, 13), maplist(random(0,10), Zs). 
Zs = [3, 1, 2, 1, 5, 3, 9, 8, 3, 7, 8, 1, 7]. 

Примечание примеси! Мы получаем разные ответы - по крайней мере, большую часть времени ...

Для воспроизводимых результатов запишите фактический prng метод и его начальное состояние, random-seed.