Ожидаемый конец заявления VBS

Question

Я новичок в VBS-скриптах. Спасибо за все ваши комментарии! Я исправил ошибку 800A0401 сейчас, благодаря вашим услугам. Но теперь я получаю ошибку 800A0414 в строке 13, символ 1 «Требуемый объект», который относится к строке: Set MimeTypesToAddArray = Array (". Manifest", "application/manifest", ".xaml", _

Теперь я понимаю, как работает подсчет строк, он подсчитывает строки комментариев. Я все еще просматриваю все ваши предложения, но если у вас есть какие-либо советы о том, как я могу исправить эту ошибку сейчас, это было бы супер!

(I do не согласен о необходимости поставить «Dim» на отдельной строке от значений типа, потому что я видел так много примеров делать это. Кто-нибудь из U VBS эксперты? 0

' This script adds the necessary Windows Presentation Foundation MIME types 
' to an IIS Server. 
' To use this script, just double-click or execute it from a command line. 
' Running this script multiple times results in multiple entries in the IIS MimeMap. 
' Set the MIME types to be added 
Dim MimeMapObj 
Dim MimeMapArray 
Dim WshShell 
Dim oExec 
Const ADS_PROPERTY_UPDATE = 2 

Dim MimeTypesToAddArray 
Set MimeTypesToAddArray = Array(".manifest", "application/manifest", ".xaml", _ 
    "application/xaml+xml", ".application", "application/x-ms-application", _ 
    ".deploy", "application/octet-stream", ".xbap", "application/x-ms-xbap", _ 
    ".xps", "application/vnd.ms-xpsdocument") 

' Get the mimemap object 
Set MimeMapObj = GetObject("IIS://LocalHost/MimeMap") 

' Call AddMimeType for every pair of extension/MIME type 
For counter = 0 to UBound(MimeTypesToAddArray) Step 2 
    AddMimeType MimeTypesToAddArray(counter), MimeTypesToAddArray(counter+1) 
Next 

' Create a Shell object 
Set WshShell = CreateObject("WScript.Shell") 

' Stop and Start the IIS Service 
Set oExec = WshShell.Exec("net stop w3svc") 
Do While oExec.Status = 0 
    WScript.Sleep 100 
Loop 

Set oExec = WshShell.Exec("net start w3svc") 
Do While oExec.Status = 0 
    WScript.Sleep 100 
Loop 

Set oExec = Nothing 

' Report status to user 
WScript.Echo "Windows Presentation Foundation MIME types have been registered." 

' AddMimeType Sub 
Sub AddMimeType(ByVal Ext, ByVal MType) 

    ' Get the mappings from the MimeMap property. 
    MimeMapArray = MimeMapObj.GetEx("MimeMap") 

    ' Add a new mapping. 
    i = UBound(MimeMapArray) + 1 
    ReDim Preserve MimeMapArray(i) 
    MimeMapArray(i) = CreateObject("MimeMap") 
    MimeMapArray(i).Extension = Ext 
    MimeMapArray(i).MimeType = MType 
    MimeMapObj.PutEx ADS_PROPERTY_UPDATE, "MimeMap", MimeMapArray 
    MimeMapObj.SetInfo() 

End Sub 

Answer 1

Я не думаю, что вы можете сгладить переменную и написать ей в той же строке.

Попробуйте их как отдельные строки:

Dim MimeTypesToAddArray 
MimeTypesToAddArray = Array(".manifest", "application/manifest", ".xaml", _ 
    "application/xaml+xml", ".application", "application/x-ms-application", _ 
    ".deploy", "application/octet-stream", ".xbap", "application/x-ms-xbap", _ 
    ".xps", "application/vnd.ms-xpsdocument") 

Answer 2

Я не знаком с VBS только VB6, но я считаю, что ошибка в том, что вы делаете DIM и назначение на одной и той же линии. VB6 не допустил этого, поэтому я полагаю, что VBS тоже. Так что, возможно, что-то вроде этого - то, что вы хотите. Также похоже, что он подсчитывает пустые строки и комментарии.

Dim MimeTypesToAddArray 
MimeTypesToAddArray = Array(".manifest", "application/manifest", ".xaml", _ 
    "application/xaml+xml", ".application", "application/x-ms-application", _ 
    ".deploy", "application/octet-stream", ".xbap", "application/x-ms-xbap", _ 
    ".xps", "application/vnd.ms-xpsdocument") 

Answer 3

Если вы собираетесь объединить Dim заявление с назначением на той же строке, вы должны сделать это следующим образом:

Dim MimeTypesToAddArray : MimeTypesToAddArray = Array()