ComboBox: кнопка на каждом элементе (для удаления элемента из списка)

Question

Мне нужно добавить кнопку (возможно, TSpeedButton?) На каждый элемент ComboBox. Когда один щелчок на кнопке, соответствующий элемент удаляется из списка. Например:

Я видел подобное обсуждение SpeedButtons в строковых сетках (здесь: TStringGrid with SpeedButtons), но я не знаю, как реализовать все эти вещи на ComboBox. Не могли бы вы дать мне несколько советов или ссылок для дальнейшего чтения по этой теме.

Answer 1

В дополнение к комментариям пользователя, в отношении которых я согласен, решение вопроса на самом деле не так уж сложно.

Вы можете сделать это, установив Style свойство csOwnerDrawFixed, рисование, самостоятельно в OnDrawItem случае, и удаление выбранного элемента в OnSelect случае, например, следующим образом:

unit Unit1; 

interface 

uses 
    Winapi.Windows, System.Classes, Vcl.Controls, Vcl.Forms, Vcl.StdCtrls, 
    Vcl.Imaging.PNGIMage; 

type 
    TForm1 = class(TForm) 
    ComboBox1: TComboBox; 
    procedure FormCreate(Sender: TObject); 
    procedure FormDestroy(Sender: TObject); 
    procedure ComboBox1DrawItem(Control: TWinControl; Index: Integer; 
     Rect: TRect; State: TOwnerDrawState); 
    procedure ComboBox1Select(Sender: TObject); 
    private 
    FDeleteGraphic: TPNGImage; 
    FDeleteRect: TRect; 
    end; 

implementation 

{$R *.dfm} 

{ TForm1 } 

procedure TForm1.ComboBox1DrawItem(Control: TWinControl; Index: Integer; 
    Rect: TRect; State: TOwnerDrawState); 
begin 
    ComboBox1.Canvas.FillRect(Rect); 
    if Index >= 0 then 
    ComboBox1.Canvas.TextOut(Rect.Left + 2, Rect.Top, ComboBox1.Items[Index]); 
    if (odSelected in State) and not (odComboBoxEdit in State) then 
    begin 
    FDeleteRect := Rect; 
    FDeleteRect.Left := FDeleteRect.Right - FDeleteGraphic.Width; 
    ComboBox1.Canvas.Draw(FDeleteRect.Left, FDeleteRect.Top, FDeleteGraphic); 
    end; 
end; 

procedure TForm1.ComboBox1Select(Sender: TObject); 
var 
    MousePos: TPoint; 
begin 
    MousePos := ComboBox1.ScreenToClient(Mouse.CursorPos); 
    MousePos.Offset(0, -ComboBox1.Height); 
    if PtInRect(FDeleteRect, MousePos) then 
    begin 
    ComboBox1.Items.Delete(ComboBox1.ItemIndex); 
    ComboBox1.Invalidate; 
    end; 
end; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    FDeleteGraphic := TPNGImage.Create; 
    FDeleteGraphic.LoadFromFile('H:\Icons\FamFam Common\Delete.png'); 
end; 

procedure TForm1.FormDestroy(Sender: TObject); 
begin 
    FDeleteGraphic.Free; 
end; 

end. 

С этим результатом :

Вы можете (повторно) сохранить предыдущий ItemIndex настройки. Настройте свои пожелания.