Конкатенация строк KDB с символьным списком для динамического запроса

Question

В этом link приведен пример включения динамического параметра. d в запросе выборки КДБ:

h: hopen`:myhost01:8012 // open connection 
d: 2016.02.15 // define date var 
symList: `GBPUSD`EURUSD 
h raze "select from MarketDepth where date=", string d, ", sym in `GBPUSD`EURUSD" // run query with parameter d 

Здесь d имеет тип date и легко струнной СЦЕПИТЬ для того, чтобы сформировать динамический запрос.

Если я хочу добавить symList как динамический параметр, а также путем преобразования в строку:

raze "select from MarketDepth where date=", string d, ", sym in ", string symList 

Сцепленная строка становится: select from MarketDepth where date=2016.02.15, sym in GBPUSDEURUSD, другими словами, конкатенация теряет кавычку поэтому запрос не выполняется , Как я могу это решить?

p.S: Я знаю о functional querying, но после провала в течение 2 часов я отказался от этого.

Answer 1

Вы правы, string SYMBOL не сохраняет характер одиночного обратную кавычки, так что вы должны будете добавить его самостоятельно, как это:

symList: `GBPUSD`EURUSD 
strSymList: "`",'string symList/("`GBPUSD";"`EURUSD") 

я присоединиться , с each-both adverb' присоединиться к с обратным одиночными кавычками каждого элемент списка. Имея свой список символ строковой динамический запрос становится

"select from MarketDepth where date=", (string d), ", sym in ",raze"`",'string symList 

Вы также можете использовать parse, чтобы увидеть, как форма функциональной формы запроса будет выглядеть следующим образом.

q) parse "select from MarketDepth where date=", (string d), ", sym in ",raze"`",'string symList 
(?;`MarketDepth;enlist ((=;`date;2016.02.15);(in;`sym;enlist `GBPUSD`EURUSD));0b;()) 

Теперь это легко создать функциональный выбор:

?[`MarketDepth;enlist ((=;`date;2016.02.15);(in;`sym;enlist symList));0b;()] 

Надеется, что это помогает.

Обновление: Решение @ Райана Гамильтона, вероятно, является лучшим в вашем конкретном сценарии. Вы можете даже сделать таблицу назвать аргумент, если вы хотите:

h({[t;d;s]select from t where date=d,sym in s};`MarketDepth; d; symList) 

Но стоит отметить, что вы не можете использовать эту технику, когда вам нужно сделать список столбцов динамических. Ниже будет НЕ работы:

h({[c;d;s]select c from t where date=d,sym in s};`time`sym; d; symList) 

Вам придется либо построить динамичную выберите выражение, как вы делаете или использовать функциональные формы.

Answer 2

Нет необходимости в функциональных отборах.

q)MarketDepth:([] date:9#2016.02.15; sym:9#`A`B) 
q)d:2016.02.15 
q)symList:`B 

q)h ({[dt;sl] select from MarketDepth where date=dt,sym in sl}; d; symList) 
date  sym 
-------------- 
2016.02.15 B 
2016.02.15 B 
2016.02.15 B 
2016.02.15 B 

Answer 3

Другие уже дали хорошие альтернативные подходы к вашей проблеме. Но в случае, если вам нужно присоединиться к строкам и символам (или другим типам данных), не теряя обратную линию, функция .Q.s1 выполняет эту задачу.

q) .Q.s1 `a`b 
q)"`a`b" 
q)"select from table where sym in ",.Q.s1 symlist 

Примечание: Как правило, это не рекомендуется использовать .Q функции пространства имен.