Преобразование языкового стандарта на язык/страну с помощью XSL

Question

Мне нужно выяснить, как лучше всего преобразовать языковые строки в удобное для пользователя имя. Я мог бы написать большой <xsl:choose> и просто добавить условие для каждой из локаций, которые хочу преобразовать, но я думаю, что, вероятно, более эффективный или умный способ.

Мой вход выглядит следующим образом:

<content name="locale" value="en_US" /> 
<content name="locale" value="ja_JP" /> 

И соответствующий выход может выглядеть следующим образом:

<content name="language" value="English" /> 
<content name="language" value="Japanese" /> 

В моем случае я не заботиться о стране прямо сейчас, только язык. Мне также не нужно проверять все возможные локали, всего 10 или около того в настоящее время, но в будущем может быть больше, поэтому я ищу наименее жесткий способ обработки конверсии.

Answer 1

Вы можете сохранить сопоставление в другом XML-файле и получить к нему доступ с помощью функции document() из вашей таблицы стилей. Если у вас есть файл сопоставления, как один из них предложил Chris McCall в его answer, вы могли бы сделать это следующим образом:

<xsl:stylesheet version="1.0" 
       xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:variable name="mapping" 
       select="document('mapping.xml')"/> 

    <xsl:template match="content[@name='locale']"> 
    <xsl:variable name="locale" select="@value"/> 
    <content name="language"> 
     <xsl:attribute name="value"> 
     <xsl:value-of 
      select="$mapping//content-map[@locale=$locale]/@language"/> 
     </xsl:attribute> 
    </content> 
    </xsl:template> 

</xsl:stylesheet> 

---

Если вы хотите действительно компактное решение, которое вы можете даже включить отображение внутри самой таблицы стилей , Поскольку XSLT-процессоры должны игнорировать любые элементы, не принадлежащие XSLT-пространству имен в элементе xsl:stylesheet, вы можете включить туда отображение. Вы можете получить доступ к самому документу XSLT как document('').

Так самодостаточным таблицы стилей с отображением может выглядеть следующим образом:

<xsl:stylesheet version="1.0" 
       xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:map="https://stackoverflow.com/questions/1428947#" 
       exclude-result-prefixes="map" 
       > 

    <map:mapping> 
    <map:content-map locale="en_US" language="English"/> 
    <map:content-map locale="ja_JP" language="Japanese"/> 
    </map:mapping> 

    <xsl:variable name="mapping" 
       select="document('')//map:mapping"/> 

    <xsl:template match="content[@name='locale']"> 
    <xsl:variable name="locale" select="@value"/> 
    <content name="language"> 
     <xsl:attribute name="value"> 
     <xsl:value-of 
      select="$mapping//map:content-map[@locale=$locale]/@language"/> 
     </xsl:attribute> 
    </content> 
    </xsl:template> 

</xsl:stylesheet> 

Answer 2

Интересный вопрос!

Как насчет промежуточного отображения XML файла ?:

<content-maps> 
<content-map locale="en_US" language="English"/> 
<content-map locale="ja_JP" language="Japanese"/> 
</content-maps> 

Использования XSL для создания ваших <xsl:choose> блока от этого и запустить результаты по сравнению с вашим входным файлом.

Answer 3

Вероятно, есть лучший способ, но вы можете иметь красиво отформатированный поиск по странам в отдельном документе XML, а затем ссылаться на эту информацию и публиковать эту информацию.

Это, по крайней мере, должно держать большой выбор заявления в страхе и дать вам варианты будущего расширения.