'Сортировать по' игнорируется в запросе LINQ

Question

Я пытаюсь сортировать список по названию компании. Я пробовал следующий код, но это сортирует список по CompID, а не CoShort. Как мне изменить это для сортировки CoShort?

Public Shared Function [SelectCompanyData](iElement() As Integer) As List(Of CompanyList) 

    Dim db As New EntryDataContext() 

    Dim q As IQueryable(Of CompanyList) = (From Act_Sub_Manfu_Link In db.Act_Sub_Manfu_Links _ 
      Join Company In db.Companies _ 
      On Act_Sub_Manfu_Link.CompID Equals Company.CompID _ 
      Where iElement.Contains(Act_Sub_Manfu_Link.ACCN) _ 
      And Company.In_Dir _ 
      Select New CompanyList With { _ 
       .CompID = Company.CompID, _ 
       .InDir = Company.In_Dir, _ 
       .CoShort = Company.CoShort _ 
       }).Distinct 

    q.OrderBy(Function(c) c.CoShort) 

    Dim list As List(Of CompanyList) = q.ToList 

    Return list 

End Function 

Answer 1

Вы должны назначить упорядоченную коллекцию в переменную:

Dim oq As IOrderedQueryable(Of CompanyList) = q.OrderBy(Function(c) c.CoShort) 

И использовать его, чтобы получить список результатов поиска:

Dim list As List(Of CompanyList) = oq.ToList() 

Answer 2

Не нужно быть отнесены ни к чему, кроме возвращаемое значение

Public Function SelectCompanyData(iElement() As Integer) As List(Of CompanyList) 
    Dim db As New EntryDataContext() 
    Return (From Act_Sub_Manfu_Link In db.Act_Sub_Manfu_Links _ 
      Join Company In db.Companies _ 
      On Act_Sub_Manfu_Link.CompID Equals Company.CompID _ 
      Where iElement.Contains(Act_Sub_Manfu_Link.ACCN) _ 
      And Company.In_Dir _ 
      Select New CompanyList With { _ 
       .CompID = Company.CompID, _ 
       .InDir = Company.In_Dir, _ 
       .CoShort = Company.CoShort _ 
       }).Distinct().OrderBy(Function(c) c.CoShort).ToList() 
End Function