Как закодировать файл любого типа в строку base64, а затем снова декодировать его в файл с помощью Lazarus/Delphi?

Question

Можете ли вы рассказать мне, как я могу это сделать? Есть ли какой-нибудь блок Freepascal, который может сделать это для меня? Мне нужно, чтобы моя программа могла хранить двоичные данные в XML-формате fileformat.

Answer 1

Используйте блок base64 и его два класса, TBase64EncodingStream и TBase64DecodingStream.

Вот simple example:

program demo; 

uses Classes, base64; 

var 
    DecodedStream: TStringStream; 
    EncodedStream: TStringStream; 
    Encoder: TBase64EncodingStream; 
    Output: string; 
begin 
    DecodedStream := TStringStream.Create('Hello World!'); 
    EncodedStream := TStringStream.Create(''); 
    Encoder  := TBase64EncodingStream.Create(EncodedStream); 
    Encoder.CopyFrom(DecodedStream, DecodedStream.Size); 

    Output := EncodedStream.DataString; 
    { Outputs 'SGVsbG8gV29ybGQh' } 
    WriteLn(Output); 

    DecodedStream.Free; 
    EncodedStream.Free; 
    Encoder.Free; 
end. 

И, в opposite direction:

program demo; 

uses Classes, base64; 

var 
    DecodedStream: TStringStream; 
    EncodedStream: TStringStream; 
    Decoder: TBase64DecodingStream; 
    Output: string; 
begin 
    EncodedStream := TStringStream.Create('SGVsbG8gV29ybGQh'); 
    DecodedStream := TStringStream.Create(''); 
    Decoder  := TBase64DecodingStream.Create(EncodedStream); 
    DecodedStream.CopyFrom(Decoder, Decoder.Size); 

    Output := DecodedStream.DataString; 
    { Outputs 'Hello World!' } 
    WriteLn(Output); 

    DecodedStream.Free; 
    EncodedStream.Free; 
    Decoder.Free; 
end. 

или encodestringbase64 и сокращения от decodestringbase64 (2.4.4+) для не потока на основе использования:

Uses Base64; 
var 
    s : AnsiString; 
Begin 
    s:=EncodeStringBase64('Hello world!'); 
    Writeln('Encoded : ',s); 
    s:=DecodeStringBase64(s); 
    Writeln('Decoded again : ',s);  
end.